&LABL    PROC  &P,1,&ADD=,&BFSZ=,&EOFA=,&ERRO=,&INDA=,&INDS=,&INDX=,   XP$D00010
               &IOA1=,&IOA2=,&IORG=,&KARG=,&KLEN=,&KLOC=,&MODE=,&OPTN=,XP$D00020
               &RCSZ=,&SKAD=,&SQCK=,&TYPE=,&UPDT=,&VRFY=,&WORK=,&VMNT=,XP$D00030
               &SEPASMB=                                                P$D00031
DTFIR    NAME  1                                                        P$D00040
         LCL   &AD,&BFS,&EOF,&INA,&INS,&INX,&IO1,&IO2,&KRG,&KLN,&MOD    P$D00050
         LCL   &OPN,&RCS,&SKD,&SQK,&TYP,&UPD,&VFY,&WRK,&ERR,&IRG,&KLC   P$D00060
         LCL   &EF,&FG,&INP,&IR,&I2,&PCA,&PCT,&MIN                      P$D00070
         LCL   &I1,&S1,&E1,&K1,&X1,&LBL,&P2A                            P$D00075
         LCL   &VMN                                                     P$D00076
&AD      SET   0                                                        P$D00080
&BFS     SET   0                                                        P$D00090
&EOF     SET   0                                                        P$D00100
&ERR     SET   0                                                        P$D00110
&INA     SET   0                                                        P$D00120
&INS     SET   0                                                        P$D00130
&INX     SET   0                                                        P$D00140
&IO1     SET   0                                                        P$D00150
&IRG     SET   0                                                        P$D00160
&KRG     SET   0                                                        P$D00170
&KLN     SET   0                                                        P$D00180
&KLC     SET   0                                                        P$D00190
&MOD     SET   0                                                        P$D00200
&OPN     SET   0                                                        P$D00210
&RCS     SET   0                                                        P$D00220
&SKD     SET   0                                                        P$D00230
&SQK     SET   0                                                        P$D00240
&TYP     SET   0                                                        P$D00250
&UPD     SET   0                                                        P$D00260
&VFY     SET   0                                                        P$D00270
&VMN     SET   0                                                        P$D00271
&WRK     SET   0                                                        P$D00280
&EF      SET   0                                                        P$D00290
&FG      SET   0                                                        P$D00300
&INP     SET   1                                                        P$D00310
&IR      SET   0                                                        P$D00320
&I2      SET   0                                                        P$D00330
&PCA     SET   1                                                        P$D00340
&PCT     SET   X'64'                                                    P$D00350
&MIN     SET   0                                                        P$D00360
&I1      SET   X'F0'                                                    P$D00365
&S1      SET   X'F0'
&E1      SET   X'F0'
&K1      SET   X'F0'
&X1      SET   X'F0'
.********************************************************************** P$D00370
&LBL     SET   '&LABL'                                                  P$D00371
         DO    ('&LABL'='')++('&LABL'>'Z999999')                        P$D00372
         DO    '&LABL'=''                                               P$D00373
&LBL     SET   ' '                                                      P$D00374
         ENDO                                                           P$D00375
         PNOTE 'P','FILENAME UNDEFINED OR GREATER THAN 7 CHARACTERS'    P$D00376
         GOTO  .M1A                                                     P$D00377
         ENDO                                                           P$D00378
         ENTRY &LABL                                                    P$D00379
         DO    '&SEPASMB'='NO'=0                                        P$D00380
         ENTRY &LABL.C                                                  P$D00382
         ENTRY &LABL.E                                                  P$D00390
         ENDO                                                           P$D00392
.M1A     LABEL                                                          P$D00400
.********************************************************************** P$D00410
         DO    '&INDX'=''                                               P$D00420
         GOTO  .M1                                                      P$D00430
         ENDO                                                           P$D00440
         DO    '&INDX'='YES'=0                                          P$D00450
         PNOTE '*','INDX INCORRECTLY SPECIFIED, YES ASSUMED'            P$D00460
         ENDO                                                           P$D00470
&INX     SET   1                                                        P$D00480
&PCT     SET   X'32'                                                    P$D00490
.M1      LABEL                                                          P$D00500
&PCA     SET   &PCA+&INX                                                P$D00510
.********************************************************************** P$D00520
         DO    '&MODE'='RAND'                                           P$D00530
&MOD     SET   1                                                        P$D00540
         GOTO  .M2                                                      P$D00550
         ENDO                                                           P$D00560
         DO    '&MODE'=''                                               P$D00570
         PNOTE '*','MODE NOT SPECIFIED, SEQ ASSUMED'                    P$D00580
         GOTO  .M2                                                      P$D00590
         ENDO                                                           P$D00600
         DO    '&MODE'='SEQ'=0                                          P$D00610
         PNOTE '*','MODE INCORRECTLY SPECIFIED, SEQ ASSUMED'            P$D00620
         ENDO                                                           P$D00630
.M2      LABEL                                                          P$D00640
.********************************************************************** P$D00650
         DO    '&TYPE'='OUTPUT'                                         P$D00660
&INP     SET   0                                                        P$D00670
&TYP     SET   1                                                        P$D00680
         GOTO  .M3                                                      P$D00690
         ENDO                                                           P$D00700
         DO    '&TYPE'=''                                               P$D00710
         PNOTE '*','TYPE NOT SPECIFIED, INPUT ASSUMED'                  P$D00720
         GOTO  .M3                                                      P$D00730
         ENDO                                                           P$D00740
         DO    '&TYPE'='INPUT'=0                                        P$D00750
         PNOTE '*','TYPE INCORRECTLY SPECIFIED, INPUT ASSUMED'          P$D00760
         ENDO                                                           P$D00770
.M3      LABEL                                                          P$D00780
.********************************************************************** P$D00790
         DO    '&WORK'=''                                               P$D00800
         DO    ((&INX=1)**((&TYP=1)++(&AD=1)))++((&MOD=1)**(&TYP=1))    P$D00810
         PNOTE 'P','WORK REQUIRED BUT NOT SPECIFIED'                    P$D00820
         GOTO  .M4                                                      P$D00830
         ENDO                                                           P$D00840
         DO    '&IORG'=''                                               P$D00850
         PNOTE 'P','WORK OR IORG REQUIRED BUT NOT SPECIFIED'            P$D00860
         GOTO  .M4                                                      P$D00870
         ENDO                                                           P$D00880
&IRG     SET   &IORG(1)                                                 P$D00890
&IR      SET   1                                                        P$D00900
         DO    (&IRG<2)++(&IRG>12)                                      P$D00910
         PNOTE 'P','IORG INCORRECTLY SPECIFIED, IGNORED'                P$D00920
&IRG     SET   0                                                        P$D00930
&IR      SET   0                                                        P$D00940
         ENDO                                                           P$D00960
         GOTO  .M4                                                      P$D00965
         ENDO                                                           P$D00970
         DO    '&WORK'='YES'=0                                          P$D00980
         PNOTE '*','WORK INCORRECTLY SPECIFIED, YES ASSUMED'            P$D00990
         ENDO                                                           P$D01000
         DO    '&IORG'=''=0                                             P$D01010
         PNOTE 'P','BOTH WORK AND IORG NOT ALLOWED, IORG IGNORED'       P$D01020
         ENDO                                                           P$D01030
&WRK     SET   1                                                        P$D01040
.M4      LABEL                                                          P$D01050
.********************************************************************** P$D01060
         DO    '&ADD'=''                                                P$D01070
         GOTO  .M5                                                      P$D01080
         ENDO                                                           P$D01090
         DO    '&ADD'='YES'=0                                           P$D01100
         PNOTE '*','ADD INCORRECTLY SPECIFIED, YES ASSUMED'             P$D01110
         ENDO                                                           P$D01120
         DO   ('&INDX'='')++(&TYP=1)                                    P$D01130
         PNOTE 'P','ADD SUPPORTED ONLY FOR KEYED INPUT FILES, IGNORED'  P$D01140
         GOTO  .M5                                                      P$D01150
         ENDO                                                           P$D01160
&AD      SET   1                                                        P$D01170
.M5      LABEL                                                          P$D01180
.********************************************************************** P$D01190
         DO    '&UPDT'=''                                               P$D01200
         GOTO  .M6                                                      P$D01210
         ENDO                                                           P$D01220
         DO    '&UPDT'='YES'=0                                          P$D01230
         PNOTE '*','UPDT INCORRECTLY SPECIFIED, YES ASSUMED'            P$D01240
         ENDO                                                           P$D01250
         DO    &TYP=1                                                   P$D01260
         PNOTE 'P','UPDT NOT SUPPORTED WITH OUTPUT, IGNORED'            P$D01270
         GOTO  .M6                                                      P$D01280
         ENDO                                                           P$D01290
&UPD     SET   1                                                        P$D01300
&INP     SET   0                                                        P$D01310
.M6      LABEL                                                          P$D01320
.********************************************************************** P$D01330
         DO    '&VRFY'=''                                               P$D01340
         GOTO  .M7                                                      P$D01350
         ENDO                                                           P$D01360
         DO    '&VRFY'='YES'=0                                          P$D01370
         PNOTE '*','VRFY INCORRECTLY SPECIFIED,YES ASSUMED'             P$D01380
         ENDO                                                           P$D01390
&VFY     SET   1                                                        P$D01400
.M7      LABEL                                                          P$D01410
.********************************************************************** P$D01420
         DO    '&SQCK'=''                                               P$D01430
         GOTO  .M8                                                      P$D01440
         ENDO                                                           P$D01450
         DO    '&SQCK'='YES'=0                                          P$D01460
         PNOTE '*','SQCK INCORRECTLY SPECIFIED, YES ASSUMED'            P$D01470
         ENDO                                                           P$D01480
         DO    '&INDX'=''                                               P$D01490
         PNOTE 'P','SQCK SUPPORTED ONLY FOR KEYED FILES, IGNORED'       P$D01500
         GOTO  .M8                                                      P$D01510
         ENDO                                                           P$D01520
&SQK     SET   1                                                        P$D01530
.M8      LABEL                                                          P$D01540
.********************************************************************** P$D01550
         DO    '&OPTN'=''                                               P$D01560
         GOTO  .M9                                                      P$D01570
         ENDO                                                           P$D01580
         DO    '&OPTN'='YES'=0                                          P$D01590
         PNOTE '*','OPTN INCORRECTLY SPECIFIED, YES ASSUMED'            P$D01600
         ENDO                                                           P$D01610
&OPN     SET   1                                                        P$D01620
.M9      LABEL                                                          P$D01630
.********************************************************************** P$D01640
         DO    '&IOA1'=''                                               P$D01650
         PNOTE 'P','IOA1 REQUIRED FOR ALL FILES'                        P$D01660
         GOTO  .M10                                                     P$D01670
         ENDO                                                           P$D01680
&IO1     SET   '&IOA1'                                                  P$D01690
&I1      SET   0                                                        P$D01695
         DO    '&SEPASMB'='NO'=0                                        P$D01696
         EXTRN &IOA1                                                    P$D01700
         ENDO                                                           P$D01702
.M10     LABEL                                                          P$D01710
.********************************************************************** P$D01720
&IO2     SET   '&IO1'                                                   P$D01730
         DO    '&IOA2'=''                                               P$D01740
         GOTO  .M11                                                     P$D01750
         ENDO                                                           P$D01760
         DO    (&UPD=1)++(&MOD=1)++(&AD=1)++((&INX=1)**(&TYP=0))        P$D01770
         PNOTE 'P','IOA2 NOT ALLOWED WITH UPDT, ADD, RANDOM MODE, OR KEXP$D01780
               YED INPUT, IGNORED'                                      P$D01781
         GOTO  .M11                                                     P$D01790
         ENDO                                                           P$D01800
&IO2     SET   '&IOA2'                                                  P$D01810
&I2      SET   1                                                        P$D01820
         DO    '&SEPASMB'='NO'=0                                        P$D01822
         EXTRN &IOA2                                                    P$D01830
         ENDO                                                           P$D01832
.M11     LABEL                                                          P$D01840
.********************************************************************** P$D01850
         DO    '&SKAD'=''                                               P$D01860
         DO    (&INX=0)**(&MOD=1)                                       P$D01870
         PNOTE 'P','SKAD REQUIRED FOR NON-KEYED RANDOM FILES'           P$D01880
         ENDO                                                           P$D01890
         GOTO  .M12                                                     P$D01900
         ENDO                                                           P$D01910
         DO    &INX=1                                                   P$D01920
         PNOTE '*','SKAD USED ONLY WITH NON-KEYED FILES, IGNORED'       P$D01930
         GOTO  .M12                                                     P$D01940
         ENDO                                                           P$D01950
&SKD     SET   '&SKAD'                                                  P$D01960
&S1      SET   0                                                        P$D01965
         DO    '&SEPASMB'='NO'=0                                        P$D01966
         EXTRN &SKAD                                                    P$D01970
         ENDO                                                           P$D01972
.M12     LABEL                                                          P$D01980
.********************************************************************** P$D01990
         DO    '&EOFA'=''                                               P$D02000
         DO    (&TYP=0)**(&MOD=0)                                       P$D02010
         PNOTE 'P','EOFA REQUIRED IF INPUT SEQUENTIAL FILE'             P$D02020
         ENDO                                                           P$D02030
         GOTO  .M12A                                                    P$D02040
         ENDO                                                           P$D02050
&EOF     SET   '&EOFA'                                                  P$D02060
&EF      SET   1                                                        P$D02070
         DO    '&SEPASMB'='NO'=0                                        P$D02072
         EXTRN &EOFA                                                    P$D02080
         ENDO                                                           P$D02082
.M12A    LABEL                                                          P$D02090
.********************************************************************** P$D02100
         DO    '&ERRO'=''                                               P$D02110
         PNOTE '*','ERROR EXIT NOT SPECIFIED, ERRORS RETURNED IN-LINE'  P$D02120
         GOTO  .M13                                                     P$D02130
         ENDO                                                           P$D02140
&ERR     SET   '&ERRO'                                                  P$D02150
&E1      SET   0                                                        P$D02155
         DO    '&SEPASMB'='NO'=0                                        P$D02156
         EXTRN &ERRO                                                    P$D02160
         ENDO                                                           P$D02162
.M13     LABEL                                                          P$D02170
.********************************************************************** P$D02180
         DO    '&KARG'=''                                               P$D02190
         DO    &INX=1                                                   P$D02200
         PNOTE 'P','KARG REQUIRED FOR KEYED FILES, BUT NOT SPECIFIED'   P$D02210
         ENDO                                                           P$D02220
         GOTO  .M14                                                     P$D02230
         ENDO                                                           P$D02240
         DO    &INX=0                                                   P$D02250
         PNOTE '*','KARG ONLY USED WITH KEYED FILES, IGNORED'           P$D02260
         GOTO  .M14                                                     P$D02270
         ENDO                                                           P$D02280
&KRG     SET   '&KARG'                                                  P$D02290
&K1      SET   0                                                        P$D02295
         DO    '&SEPASMB'='NO'=0                                        P$D02296
         EXTRN &KARG                                                    P$D02300
         ENDO                                                           P$D02302
.M14     LABEL                                                          P$D02310
.********************************************************************** P$D02320
         DO    '&KLEN'=''                                               P$D02330
         DO    &INX=1                                                   P$D02340
         PNOTE 'P','KLEN REQUIRED FOR KEYED FILES, BUT NOT SPECIFIED'   P$D02350
         ENDO                                                           P$D02360
         GOTO  .M15                                                     P$D02370
         ENDO                                                           P$D02380
         DO    &INX=0                                                   P$D02390
         PNOTE '*','KLEN ONLY USED WITH KEYED FILES, IGNORED'           P$D02400
         GOTO  .M15                                                     P$D02410
         ENDO                                                           P$D02420
         DO    (&KLEN<3)++(&KLEN>80)                                    P$D02430
         PNOTE 'P','KLEN SPECIFIED INCORRECTLY'                         P$D02440
         GOTO  .M15                                                     P$D02450
         ENDO                                                           P$D02460
&KLN     SET   &KLEN                                                    P$D02470
.M15     LABEL                                                          P$D02480
.********************************************************************** P$D02490
         DO    '&INDA'=''                                               P$D02500
         DO    &INX=1                                                   P$D02510
         PNOTE 'P','INDA REQUIRED FOR KEYED FILES, BUT NOT SPECIFIED'   P$D02520
         ENDO                                                           P$D02530
         GOTO  .M16                                                     P$D02540
         ENDO                                                           P$D02550
         DO    &INX=0                                                   P$D02560
         PNOTE '*','INDA ONLY USED WITH KEYED FILES, IGNORED'           P$D02570
         GOTO  .M16                                                     P$D02580
         ENDO                                                           P$D02590
&INA     SET   '&INDA'                                                  P$D02600
&X1      SET   0                                                        P$D02605
         DO    '&SEPASMB'='NO'=0                                        P$D02606
         EXTRN &INDA                                                    P$D02610
         ENDO                                                           P$D02612
.M16     LABEL                                                          P$D02620
.********************************************************************** P$D02630
         DO    '&INDS'=''                                               P$D02640
         DO    &INX=1                                                   P$D02650
         PNOTE 'P','INDS REQUIRED FOR KEYED FILES, BUT NOT SPECIFIED'   P$D02660
         ENDO                                                           P$D02670
         GOTO  .M17                                                     P$D02680
         ENDO                                                           P$D02690
         DO    &INX=0                                                   P$D02700
         PNOTE '*','INDS ONLY USED WITH KEYED FILES, IGNORED'           P$D02710
         GOTO  .M17                                                     P$D02720
         ENDO                                                           P$D02730
&INS     SET   &INDS                                                    P$D02740
         DO    (&INS<256)++(&INS=(&INS/256)*256=0)                      P$D02750
         PNOTE 'P','INDS LESS THAN OR NOT MULTIPLE OF 256'              P$D02760
         ENDO                                                           P$D02770
.M17     LABEL                                                          P$D02780
.********************************************************************** P$D02781
         DO    '&RCSZ'=''                                               P$D02782
         PNOTE 'P','RCSZ REQUIRED FOR ALL FILES'                        P$D02783
         GOTO  .M19                                                     P$D02784
         ENDO                                                           P$D02785
&RCS     SET   &RCSZ                                                    P$D02786
.M19     LABEL                                                          P$D02787
.********************************************************************** P$D02790
         DO    '&KLOC'=''                                               P$D02800
         DO    &INX=1                                                   P$D02810
         PNOTE 'P','KLOC NOT SPECIFIED, ZERO ASSUMED'                   P$D02820
         ENDO                                                           P$D02830
         GOTO  .M18                                                     P$D02840
         ENDO                                                           P$D02850
         DO    &INX=0                                                   P$D02860
         PNOTE '*','KLOC ONLY USED WITH KEYED FILES, IGNORED'           P$D02870
         GOTO  .M18                                                     P$D02880
         ENDO                                                           P$D02890
&KLC     SET   &KLOC                                                    P$D02900
         DO    (&KLC+&KLN)>&RCS                                         P$D02910
         PNOTE 'P','LOCATION AND LENGTH OF KEY WILL EXCEED RECORD SIZE' P$D02920
         ENDO                                                           P$D02930
.M18     LABEL                                                          P$D02940
.********************************************************************** P$D02950
         DO    '&BFSZ'=''                                               P$D03030
         PNOTE 'P','BFSZ REQUIRED BUT NOT SPECIFIED'                    P$D03040
         GOTO  .M22                                                     P$D03050
         ENDO                                                           P$D03060
&BFS     SET   &BFSZ                                                    P$D03070
         DO    (&BFS<256)++(&BFS=(&BFS/256)*256=0)                      P$D03080
         PNOTE 'P','BFSZ LESS THAN OR NOT MULTIPLE OF 256'              P$D03090
         ENDO                                                           P$D03100
         DO    &RCS>256                                                 P$D03110
         DO    &RCS=(&RCS/256)*256=0                                    P$D03120
         GOTO  .M20                                                     P$D03130
         ENDO                                                           P$D03140
&MIN     SET   &RCS                                                     P$D03150
         GOTO  .M21                                                     P$D03160
         ENDO                                                           P$D03170
         DO    &RCS=0                                                   P$D03180
         GOTO  .M22                                                     P$D03190
         ENDO                                                           P$D03200
         DO    (256/&RCS)*&RCS=256                                      P$D03210
&MIN     SET   256                                                      P$D03220
         GOTO  .M21                                                     P$D03230
         ENDO                                                           P$D03240
.M20     LABEL                                                          P$D03250
&MIN     SET   ((&RCS+255)/256)*256+(256*((&RCS+255)=((&RCS+255)/256)*2XP$D03260
               56=0))                                                   P$D03270
.M21     LABEL                                                          P$D03280
         DO    &MIN>&BFS                                                P$D03290
         PNOTE 'P','BFSZ LESS THAN MINIMUM REQUIREMENT OF &MIN'         P$D03300
         ENDO                                                           P$D03310
.M22     LABEL                                                          P$D03320
.********************************************************************** P$D03330
         DO    '&VMNT'=''                                               P$D03331
         GOTO  .M23                                                     P$D03332
         ENDO                                                           P$D03333
         DO    '&VMNT'='ONE'=0                                          P$D03334
         PNOTE '*','VMNT INCORRECTLY SPECIFIED, ONE ASSUMED'            P$D03335
         ENDO                                                           P$D03336
         DO    &MOD=1                                                   P$D03337
         PNOTE 'P','VMNT NOT ALLOWED IN RANDOM MODE, IGNORED'           P$D03338
         GOTO  .M23                                                     P$D03339
         ENDO                                                           P$D03340
&VMN     SET   1                                                        P$D03341
.M23     LABEL                                                          P$D03342
.********************************************************************** P$D03343
         CNOP  0,8                                                      P$D03344
         EXTRN D3$I&INX.&INX.&INX                                       P$D03380
&LABL    DC    X'00008048'              CCB                             P$D03390
         DC    6F'0'                                                    P$D03391
         DC    CL7'&LBL'                FILENAME            DC$NME(8)   P$D03400
         DC    CL1' '                                                   P$D03410
&FG      SET   64+(&VMN*2)                                              P$D03420
         DC    YL2(&FG)                 MODULE FLAGS        DC$MFLG(2)  P$D03421
         DC    8X'0'                                                    P$D03422
         DC    X'90'                    TYPE CODE           DC$DTF(3)   P$D03430
         DC    X'&INX.&INX.&INX.&INX'                                   P$D03440
         DC    3X'0'                                                    P$D03450
         DC    A(D3$I&INX.&INX.&INX)    IOCS MODULE ADDR    DC$IOCS(4)  P$D03455
&LABL.E  DC    6F'0'                                                    P$D03460
         DC    YL1(&PCA)                PCA COUNT           DC$PCACT(1) P$D03470
         DC    11X'0'                                                   P$D03480
         DC    YL1(1)                   ADDR OF PCA1        DC$PCA1(4)  P$D03490
         DC    AL3(&LABL+160)                                           P$D03495
         DO    &INX=1                                                   P$D03500
         DC    X'02'                    ADDR OF PCA2        DC$PCA2(4)
         DC    AL3(&LABL+240)
         GOTO  .I1
         ENDO
         DC    A(0)                     ADDR OF PCA2        DC$PCA2(4)
.I1      LABEL
         DC    22X'0'                                                   P$D03510
&FG      SET   (128*&TYP)+(64*&INP)+(32*&UPD)+(16*&OPN)                 P$D03520
&FG      SET   &FG+(8*&INX)+(4*&MOD)+(2*&SQK)+&AD                       P$D03530
         DC    YL1(&FG)                 FLAG BYTE           D3$FG3(1)   P$D03540
         DC    X'0'                                                     P$D03550
         DC    YL2(&BFS)                SPEC BUF SIZE       D3$DBFS(2)  P$D03560
         DC    14X'0'                                                   P$D03570
         DC    YL1(&E1)                 USER ERROR EXIT     D3$ERR(4)   P$D03580
         DC    AL3(&ERR)
&LABL.C  DC    15X'0'                                                   P$D03590
&FG      SET   (128*&I2)+(64*&WRK)+(32*&IR)+(16*&EF)                    P$D03600
         DC    YL1(&FG)                 PROCESSOR FLAG      D3$DFG1(1)  P$D03610
         DC    4F'0'                                                    P$D03620
         DC    YL1(&I1)                 IOA1 ADDRESS        D3$DA1(4)   P$D03630
         DC    AL3(&IO1)
         DC    X'0100'                  SECTOR SIZE         D3$DBKS(2)  P$D03640
         DC    X'0'                                                     P$D03650
         DC    X'01'                    SECTORS/BLOCK       D3$DSPB(1)  P$D03660
         DC    2X'0'                                                    P$D03670
         DC    X'0064'                  SECONDARY ALLOC %   D3$DUOS(2)  P$D03680
         DC    YL2(&PCT)                INIT ALLOC %        D3$DSIZE(4) P$D03690
         DC    2X'0'                                                    P$D03700
&FG      SET   1+(&VFY*16)                                              P$D03710
         DC    YL1(&FG)                 PCA FLAGS           D3$DEODA(4) P$D03720
         DC    AL3(&EOF)                EOF ADDRESS                     P$D03730
         DC    YL1(&S1)                 SEEK ADDRESS        D3$DSKAD(4) P$D03740
         DC    AL3(&SKD)
         DC    YL1(&I1)                 IOA2 ADDRESS        D3$DA2(4)   P$D03750
         DC    AL3(&IO2)
         DC    F'&RCS'                  RECORD SIZE         D3$DREC(4)  P$D03760
         DC    26X'0'                                                   P$D03770
&FG      SET   20+(&IRG*4)                                              P$D03780
         DC    YL2(&FG)                 IORG DISPLACEMENT   D3$DSTRG(2) P$D03790
         DC    F'0'                                                     P$D03800
         DO    &INX=1                                                   P$D03810
         DC    4F'0'                                                    P$D03820
         DC    YL1(&X1)                 INDEX BUFFER ADDR   D3$XBUF(4)  P$D03830
         DC    AL3(&INA)
         DC    X'0100'                  INDEX PCA BLK SIZE  D3$XBPB(2)  P$D03840
         DC    X'0'                                                     P$D03850
         DC    X'01'                    SECTORS/BLOCK       D3$XSPB(1)  P$D03860
         DC    YL2(&KLN)                KEY LENGTH          D3$XKSZ(2)  P$D03870
         DC    X'0001'                  % SECONDARY ALLOC   D3$XUOS(2)  P$D03880
         DC    X'00010000'              % INITIAL ALLOC     D3$XADJ(4)  P$D03890
         DC    X'03'                    PCA FLAGS           D3$XPFG(1)  P$D03900
         DC    3X'0'                                                    P$D03910
         DC    YL1(&K1)                 KEY FIELD ADDR      D3$XKARG(4) P$D03920
         DC    AL3(&KRG)
         DC    6X'0'                                                    P$D03930
         DC    YL2(&INS)                INDEX BUFFER SIZE   D3$XTSIZ(2) P$D03931
         DC    YL2(&KLC)                KEY LOCATION        D3$XILOC(2) P$D03940
         DC    YL1(&KLN)                KEY LENGTH          D3$XREME(1) P$D03950
         DC    13X'0'                                                   P$D03960
         DC    XL(&KLN+3)'0'            STRG FOR HIKEY/PTR  D3$XHIK     P$D03970
         ENDO                                                           P$D03980
         END                                                            P$D03990
