Import('env', 'install_perms')
from os.path import join, basename

languages = []
for src in env.Glob('*.po'):
    lang = basename(str(src))[:-3]
    languages.append(lang)
    dst = join(lang, "LC_MESSAGES", 'mypaint.mo')
    env.Command(dst, src, 'msgfmt $SOURCE -o $TARGET')

# translations
for lang in languages:
    install_perms(env, '$prefix/share/locale/%s/LC_MESSAGES' % lang,
                 '%s/LC_MESSAGES/mypaint.mo' % lang)

lang = ARGUMENTS.get('translate')
if lang:
    env.Execute('git grep --full-name --files-with-matches "^from gettext import" .. | sort > POTFILES.in')
    env.Execute('intltool-extract --local --type=gettext/glade ../gui/mypaint.xml')
    env.Execute('intltool-extract --local --type=gettext/glade ../gui/*.glade')
    env.Execute('echo po/tmp/mypaint.xml.h >> POTFILES.in')
    env.Execute('intltool-update -g mypaint --pot')
    if lang == 'all':
        translate = languages
    elif lang == 'pot':
        translate = []
    else:
        translate = [lang]
    for lang in translate:
        env.Execute('intltool-update -g mypaint %s' % lang)
    env.Execute('rm -rf tmp')
    # don't build any targets
    Exit()

Return('languages')

# vim:syntax=python
