URI(3)

NAME
URI - Uniform Resource Identifiers (absolute and relative)

SYNOPSIS
 $u1 = URI->new("http://www.perl.com");
 $u2 = URI->new("foo", "http");
 $u3 = $u2->abs($u1);
 $u4 = $u3->clone;
 $u5 = URI->new("HTTP://WWW.perl.com:80")->canonical;

 $str = $u->as_string;
 $str = "$u";

 $scheme = $u->scheme;
 $opaque = $u->opaque;
 $path   = $u->path;
 $frag   = $u->fragment;

 $u->scheme("ftp");
 $u->host("ftp.perl.com");
 $u->path("cpan/");

DESCRIPTION
This module implements the "URI" class. Objects of this class represent "Uniform Resource Identifier references" as specified in RFC 2396 (and updated by RFC 2732).

A Uniform Resource Identifier is a compact string of characters for identifying an abstract or physical resource. A Uniform Resource Identifier can be further classified either a Uniform Resource Locator (URL) or a Uniform Resource Name (URN). The distinction between URL and URN does not matter to the "URI" class interface. A "URI-reference" is a URI that may have additional information attached in the form of a fragment identifier.

An absolute URI reference consists of three parts. A scheme, a scheme specific part and a fragment identifier. A subset of URI references share a common syntax for hierarchical namespaces. For these the scheme specific part is further broken down into authority, path and query components. These URI can also take the form of relative URI references, where the scheme (and usually also the authority) component is missing, but implied by the context of the URI reference. The three forms of URI reference syntax are summarized as follows:

  <scheme>:<scheme-specific-part>#<fragment>
  <scheme>://<authority><path>?<query>#<fragment>
  <path>?<query>#<fragment>

The components that a URI reference can be divided into depend on the scheme. The "URI" class provides methods to get and set the individual components. The methods available for a specific "URI" object depend on the scheme.

CONSTRUCTORS
The following methods construct new "URI" objects:

$uri = URI->new( $str, [$scheme] )
    This class method constructs a new URI object. The string representation of a URI is given as argument together with an optional scheme specification. Common URI wrappers like "" and <>, as well as leading and trailing white space, are automatically removed from the $str argument before it is processed further.

    The constructor determines the scheme, maps this to an appropriate URI subclass, constructs a new object of that class and returns it.

    The $scheme argument is only used when $str is a relative URI. It can either be a simple string that denotes the scheme, a string containing an absolute URI reference or an absolute "URI" object. If no $scheme is specified for a relative URI $str, then $str is simply treated as a generic URI (no scheme specific methods available).

    The set of characters available for building URI references is restricted (see URI::Escape). Characters outside this set are automatically escaped by the URI constructor.

$uri = URI->new_abs( $str, $base_uri )
    This constructs a new absolute URI object. The $str argument can denote a relative or absolute URI. If relative, then it will be absolutized using $base_uri as base. The $base_uri must be an absolute URI.

$uri = URI::file->new( $filename, [$os] )
    This constructs a new file URI from a file name. See URI::file.

$uri = URI::file->new_abs( $filename, [$os] )
    This constructs a new absolute file URI from a file name. See URI::file.

$uri = URI::file->cwd
    This returns the current working directory as a file URI. See URI::file.

$uri->clone
    This method returns a copy of the $uri.

COMMON METHODS
The methods described in this section are available for all "URI" objects.

Methods that give access to components of a URI will always return the old value of the component. The value returned will be "undef" if the component was not present. There is generally a difference between a component that is empty (represented as "") and a component that is missing (represented as "undef"). If an accessor method is given an argument it will update the corresponding component in addition to returning the old value of the component. Passing an undefined argument will remove the component (if possible). The description of the various accessor methods will tell if the component is passed as an escaped or an unescaped string. Components that can be further divided into sub-parts are usually passed escaped, as unescaping might change its semantics.

The common methods available for all URI are:

$uri->scheme( [$new_scheme] )
    This method sets and returns the scheme part of the $uri. If the $uri is relative, then $uri->scheme returns "undef". If called with an argument, it will update the scheme of $uri, possibly changing the class of $uri, and return the old scheme value. The method croaks if the new scheme name is illegal; scheme names must begin with a letter and must consist of only US-ASCII letters, numbers, and a few special marks: ".", "+", "-". This restriction effectively means that scheme have to be passed unescaped. Passing an undefined argument to the scheme method will make the URI relative (if possible).

    Letter case does not matter for scheme names. The string returned by $uri->scheme is always lowercase. If you want the scheme just as it was written in the URI in its original case, you can use the $uri->_scheme method instead.

$uri->opaque( [$new_opaque] )
    This method sets and returns the scheme specific part of the $uri (everything between the scheme and the fragment) as an escaped string.

$uri->path( [$new_path] )
    This method sets and returns the same value as $uri->opaque unless the URI supports the generic syntax for hierarchical namespaces. In that case the generic method is overridden to set and return the part of the URI between the host name and the fragment.

$uri->fragment( [$new_frag] )
    This method returns the fragment identifier of a URI reference as an escaped string.

$uri->as_string
    This method returns a URI object to a plain string. URI objects are also converted to plain strings automatically by overloading. This means that $uri objects can be used as plain strings in most Perl constructs.

$uri->canonical
    This method will return a normalized version of the URI. The rules for normalization are scheme dependent. It usually involves lowercasing of the scheme and the Internet host name components, removing the explicit port specification if it matches the default port, uppercasing all escape sequences, and unescaping octets that can be better represented as plain characters.

    For efficiency reasons, if the $uri already was in normalized form, then a reference to it is returned instead of a copy.

$uri->eq( $other_uri )
URI::eq( $first_uri, $other_uri )
    This method tests whether two URI references are equal. URI references that normalize to the same string are considered equal. The method can also be used as a plain function which can also test two string arguments.

    If you need to test whether two "URI" object references denote the same object, use the '==' operator.

$uri->abs( $base_uri )
    This method returns an absolute URI reference. If $uri already is absolute, then a reference to it is simply returned. If the $uri is relative, then a new absolute URI is constructed by combining the $uri and the $base_uri, and returned.

$uri->rel( $base_uri )
    This method returns a relative URI reference if it is possible to make one that denotes the same resource relative to $base_uri. If not, then $uri is simply returned.

GENERIC METHODS
The following methods are available to schemes that use the common/generic syntax for hierarchical namespaces. The description of schemes below will tell which one these are. Unknown schemes are assumed to support the generic syntax, and therefore the following methods:

$uri->authority( [$new_authority] )
    This method sets and returns the escaped authority component of the $uri.

$uri->path( [$new_path] )
    This method sets and returns the escaped path component of the $uri (the part between the host name and the query or fragment). The path will never be undefined, but it can be the empty string.

$uri->path_query( [$new_path_query] )
    This method sets and returns the escaped path and query components as a single entity. The path and the query are separated by a "?" character, but the query can itself contain "?".

$uri->path_segments( [$segment,...] )
    This method sets and returns the path. In scalar context it returns the same value as $uri->path. In list context it will return the unescaped path segments that make up the path. Path segments that have parameters are returned as an anonymous array. The first element is the unescaped path segment proper. Subsequent elements are escaped parameter strings. Such an anonymous array uses overloading so it can be treated as a string too, but this string does not include the parameters.

$uri->query( [$new_query] )
    This method sets and returns the escaped query component of the $uri.

$uri->query_form( [$key => $value,...] )
    This method sets and returns query components that use the application/x-www-form-urlencoded format. Key/value pairs are separated by "&" and the key is separated from the value with a "=" character.

$uri->query_keywords( [$keywords,...] )
    This method sets and returns query components that use the keywords separated by "+" format.

SERVER METHODS
Schemes where the authority component denotes a Internet host will have the following methods available in addition to the generic methods.

$uri->userinfo( [$new_userinfo] )
    This method sets and returns the escaped userinfo part of the authority component.

    For some schemes this will be a user name and a password separated by a colon. This practice is not recommended. Embedding passwords in clear text (such as URI) has proven to be a security risk in almost every case where it has been used.

$uri->host( [$new_host] )
    This method sets and returns the unescaped hostname.

    If the $new_host string ends with a colon and a number, then this number will also set the port.

$uri->port( [ $new_port] )
    This method sets and returns the port. The port is simple integer that should be greater than 0.

    If no explicit port is specified in the URI, then the default port of the URI scheme is returned. If you don't want the default port substituted, then you can use the $uri->_port method instead.

$uri->host_port( [ $new_host_port ] )
    This method sets and returns the host and port as a single unit. The returned value will include a port, even if it matches the default port. The host part and the port part is separated with a colon; ":".

$uri->default_port
    This method returns the default port of the URI scheme that $uri belongs to. For http this will be the number 80, for ftp this will be the number 21, etc. The default port for a scheme can not be changed.

SCHEME SPECIFIC SUPPORT
The following URI schemes are specifically supported. For "URI" objects not belonging to one of these you can only use the common and generic methods.

data:
    The data URI scheme is specified in RFC 2397. It allows inclusion of small data items as "immediate" data, as if it had been included externally.

    "URI" objects belonging to the data scheme support the common methods and two new methods to access their scheme specific components; $uri->media_type and $uri->data. See URI::data for details.

file:
    An old specification of the file URI scheme is found in RFC 1738. A new RFC 2396 based specification in not available yet, but file URI references are in common use.

    "URI" objects belonging to the file scheme support the common and generic methods. In addition they provide two methods to map file URI back to local file names; $uri->file and $uri->dir. See URI::file for details.

ftp:
    An old specification of the ftp URI scheme is found in RFC 1738. A new RFC 2396 based specification in not available yet, but ftp URI references are in common use.

    "URI" objects belonging to the ftp scheme support the common, generic and server methods. In addition they provide two methods to access the userinfo sub-components: $uri->user and $uri->password.

gopher:
    The gopher URI scheme is specified in <draft-murali-url-gopher-1996-12-04> and will hopefully be available as a RFC 2396 based specification.

    "URI" objects belonging to the gopher scheme support the common, generic and server methods. In addition they support some methods to access gopher specific path components: $uri->gopher_type, $uri->selector, $uri->search, $uri->string.

http:
    The http URI scheme is specified in RFC 2616. The scheme is used to reference resources hosted by HTTP servers.

    "URI" objects belonging to the http scheme support the common, generic and server methods.

https:
    The https URI scheme is a Netscape invention which is commonly implemented. The scheme is used to reference HTTP servers through SSL connections. Its syntax is the same as http, but the default port is different.

ldap:
    The ldap URI scheme is specified in RFC 2255. LDAP is the Lightweight Directory Access Protocol. An ldap URI describes an LDAP search operation to perform to retrieve information from an LDAP directory.

    "URI" objects belonging to the ldap scheme support the common, generic and server methods as well as specific ldap methods; $uri->dn, $uri->attributes, $uri->scope, $uri->filter, $uri->extensions. See URI::ldap for details.

mailto:
    The mailto URI scheme is specified in RFC 2368. The scheme was originally used to designate the Internet mailing address of an individual or service. It has (in RFC 2368) been extended to allow setting of other mail header fields and the message body.

    "URI" objects belonging to the mailto scheme support the common methods and the generic query methods. In addition they support the following mailto specific methods: $uri->to, $uri->headers.

news:
    The news, nntp and snews URI schemes are specified in <draft-gilman-news-url-01> and will hopefully be available as a RFC 2396 based specification soon.

    "URI" objects belonging to the news scheme support the common, generic and server methods. In addition they provide some methods to access the path: $uri->group and $uri->message.

nntp:
    See news scheme.

pop:
    The pop URI scheme is specified in RFC 2384. The scheme is used to reference a POP3 mailbox.

    "URI" objects belonging to the pop scheme support the common, generic and server methods. In addition they provide two methods to access the userinfo components: $uri->user and $uri->auth

rlogin:
    An old specification of the rlogin URI scheme is found in RFC 1738. "URI" objects belonging to the rlogin scheme support the common, generic and server methods.

rtsp:
    The rtsp URL specification can be found in section 3.2 of RFC 2326. "URI" objects belonging to the rtsp scheme support the common, generic, and server methods, with the exception of userinfo and query-related sub-components.

rtspu:
    The rtspu URI scheme is used to talk to RTSP servers over UDP instead of TCP. The syntax is the same as rtsp.

rsync:
    Information about rsync is available from http://rsync.samba.org. "URI" objects belonging to the rsync scheme support the common, generic and server methods. In addition they provide methods to access the userinfo sub-components: $uri->user and $uri->password.

sip:
    The sip URI specification is described in sections 19.1 and 25 of RFC 3261. "URI" objects belonging to the sip scheme support the common, generic, and server methods with the exception of path related sub-components. In addition, they provide two methods to get and set sip parameters, $uri->params_form and $uri->params.

sips:
    See sip scheme. Its syntax is the same as sip, but the default port is different.

snews:
    See news scheme. Its syntax is the same as news, but the default port is different.

telnet:
    An old speficication of the telnet URI scheme is found in RFC 1738. "URI" objects belonging to the telnet scheme support the common, generic and server methods.

ssh:
    Information about ssh is available at http://www.openssh.com/. "URI" objects belonging to the ssh scheme support the common, generic and server methods. In addition they provide methods to access the userinfo sub-components: $uri->user and $uri->password.

urn:
    The syntax of Uniform Resource Names is specified in RFC 2141. "URI" objects belonging to the urn scheme provide the common methods and the methods: $uri->nid and $uri->nss that returns the Namespace Identifier and the Namespace Specific String respectively.

    The Namespace Identifier basically works like the Scheme identifier of URIs, and further divides the URN namespace. Namespace Identifier assignments are maintained at <http://www.iana.org/assignments/urn-namespaces>.

    Letter case is not significant for the Namespace Identifier. It is always returned in lower case by the $uri->nid method. The $uri->_nid method can be used if you want it in its original case.

urn:isbn:
    The "urn:isbn:" namespace contains International Standard Book Numbers (ISBNs) and is described in RFC 3187. "URI" object belonging to this namespace has the following extra methods (if the Business::ISBN module is available); $uri->isbn, $uri->isbn_publisher_code, $uri->isbn_country_code, $uri->isbn_as_ean.

urn:oid:
    The "urn:oid:" namespace contains Object Identifiers (OIDs) and is described in RFC 3061. An object identifier is sequences of digits separated by dots. "URI" object belonging to this namespace has an additional method called $uri->oid that can be used to get/set the oid value. In list context oid numbers are returned as separate elements.

CONFIGURATION VARIABLES
The following configuration variables influence how the class and its methods behave:

$URI::ABS_ALLOW_RELATIVE_SCHEME
    Some older parsers used to allow the scheme name to be present in the relative URL if it was the same as the base URL scheme. RFC 2396 says that this should be avoided, but you can enable this old behaviour by setting the $URI::ABS_ALLOW_RELATIVE_SCHEME variable to a TRUE value. The difference is demonstrated by the following examples:

      URI->new("http:foo")->abs("http://host/a/b")
          ==>  "http:foo"

      local $URI::ABS_ALLOW_RELATIVE_SCHEME = 1;
      URI->new("http:foo")->abs("http://host/a/b")
          ==>  "http:/host/a/foo"

$URI::ABS_REMOTE_LEADING_DOTS
    You can also have the abs() method ignore excess ".." segments in the relative URI by setting $URI::ABS_REMOTE_LEADING_DOTS to a TRUE value. The difference is demonstrated by the following examples:

      URI->new("../../../foo")->abs("http://host/a/b")
          ==> "http://host/../../foo"

      local $URI::ABS_REMOTE_LEADING_DOTS = 1;
      URI->new("../../../foo")->abs("http://host/a/b")
          ==> "http://host/foo"

BUGS
Using regexp variables like $1 directly as argument to the URI methods do not work too well with current perl implementations. I would argue that this is actually a bug in perl. The workaround is to quote them. E.g.:

   /(...)/ || die;
   $u->query("$1");

PARSING URIs WITH REGEXP
As an alternative to this module, the following (official) regular expression can be used to decode a URI:

  my($scheme, $authority, $path, $query, $fragment) =
  $uri =~ m|^(?:([^:/?#]+):)?(?://([^/?#]*))?([^?#]*)(?:\?([^#]*))?(?:#(.*))?|;

SEE ALSO
URI::file, URI::WithBase, URI::Escape, URI::Heuristic

RFC 2396: "Uniform Resource Identifiers (URI): Generic Syntax", Berners-Lee, Fielding, Masinter, August 1998.

http://www.iana.org/assignments/uri-schemes

http://www.iana.org/assignments/urn-namespaces

http://www.w3.org/Addressing/

COPYRIGHT
Copyright 1995-2002 Gisle Aas.

Copyright 1995 Martijn Koster.

This program is free software; you can redistribute it and/or modify it under the same terms as Perl itself.

AUTHORS / ACKNOWLEDGEMENTS
This module is based on the "URI::URL" module, which in turn was (distantly) based on the "wwwurl.pl" code in the libwww-perl for perl4 developed by Roy Fielding, as part of the Arcadia project at the University of California, Irvine, with contributions from Brooks Cutter.

"URI::URL" was developed by Gisle Aas, Tim Bunce, Roy Fielding and Martijn Koster with input from other people on the libwww-perl mailing list.

"URI" and related subclasses was developed by Gisle Aas.