         SYSTEM   BPM
R8       EQU      8
SR1      EQU      8
R3       SET      3
R15      SET      15                SHOULD PUT EM IN ORDER
R4       SET      4                  I GUESS
R5       SET      5
R6       SET      6                 SINCE I'M USING THEM ALL
R2       SET      2
R1       SET      1
R10      SET      10
R11      SET      11
R7       SET      7
R12      SET      12
R13      SET      13
RC       SET      7                 COUNT OF INPUT DIGITS WANTED
IN       SET      6                  INDEX REGISTER FOR CONVERSIONS
RL       SET      12                  LINK TO THIS LOOP
RN       SET      13                   LINK TO NEXT LOOP
RW       SET      5                     DIGITS THIS PARAMETER
RX       SET      4                 DIGITS THIS FIELD
         DEF      S1,S2,S3,S4,S5,ER1,AB1,ER2,AB2,SPILLEOF,FPT1
         DEF      WHAT,NOFILE,BUFFER
         DEF      SPILL2,SPILL3,LOOP1,ELOOP1A,ELOOP1B
         DEF      ELOOP1
         DEF      START1,INPUT,FPTSLOT,PARSE
         DEF      TYC,DELMODE,SAVMODE,VLP1,EXIT
         DEF      FILE1E,HELPIT,OPEN,SPILLNOW
         DEF      LOOP3,LOOP4,LOOP5
         DEF      LENGTH,FPT2,FPTY,FPTX
         DEF      FILLIT,FILL1,FILL2,FILL3,FILL4,FILL5,EOF2
         DEF      FILE2E,FILE2A
         REF      M:SI,M:SO,M:EI
         REF      M:EO,M:LO
         DEF      PATCH,NXTCR,CHECK,AUTO
START1   EQU      %
         LI,R1    0
         LI,R2    SPFLGEND-SPFLG    ZERO FLAGS
         STW,R1   SPFLG,R2
         BDR,R2   %-1
         M:KEYIN  (MESS,MSG1),(REPLY,INPUT),(SIZE,34),(ECB,JUNK)
PARSE    EQU      %
         LI,RC    1
         LB,RW    INPUT,RC          SEE IF HELP
         CI,RW    C'H'
         BE       HELPIT
         LB,RC    INPUT              NOW SEE COMMAND
         CI,RC    34                LOOK LIKE SPILL
         BE       SPILLIT            YES
         CI,RC    10                  HOW ABOUT FILL
         BE       FILLIT               OK.
         B        EXIT              ALL DONE.
SPILLIT  BDR,RC   %+1
         LB,RW    INPUT,RC          WHAT MODE WANTED
         CI,RW    C'D'
         BE       DELMODE           DELETE AS WE GO
         CI,RW    C'S'
         BE       SAVMODE           SAVE AS WE COPY
         CI,RW    C'A'              IS IT AUTO COPY ALL
         BNE      START1             NOPE.
         STW,RW   AUTO
         B        SAVMODE
DELMODE  LW,R11   TYC+1
         AND,R11  =X'FFFFFF00'
         AI,R11   X'40'
         STW,R11  TYC+1
*
         LW,R11   BASEFPT1          NOW SET RBBAT UP ALSO
         AND,R11  =X'FFFFFF00'
         AI,R11   X'40'
         STW,R11  BASEFPT1
         B        SPILL2
SAVMODE  LW,R11   TYC+1
         AND,R11  =X'FFFFFF00'
         AI,R11   X'10'
         STW,R11  TYC+1
         LW,R11   BASEFPT1          NOW SET RBBAT UP ALSO
         AND,R11  =X'FFFFFF00'
         AI,R11   X'10'
         STW,R11  BASEFPT1
         B        SPILL2
SPILL2   BDR,RC   %+1
         LB,RW    INPUT,RC
         CI,RW    C','
         BNE      START1            SYNTAX ERROR
         LI,R2    X'04'
         LW,R3    INPUT+7           GET FILE NAME
         SLD,R2   24                 AND BUILD VLP
         OR,R3    =C'   '             FOR LATER OPEN
         STW,R2   VLP1+1
         STW,R3   VLP1+2
         STW,R2   VLP3+1            FOR TEST OPEN
         STW,R3   VLP3+2            FOR OVERWRITE CHECK.
         LI,R2    0                 OK LETS CLEAR THE FPT
         LI,R3    8
         STW,R2   FPT1,R3
         BDR,R3   %-1
         LI,R3    FPT1+3
         STW,R3   FPTSLOT           FOR ENTERING PARAMETERS
         LI,R3    C'C2'              STREAM WE USE
         STW,R3   FPT1+2
         LW,R2    BASEFPT1          X'90080000'
         STW,R2   FPT1+1            BASIC STUFF REQUIRED
         AI,RC    -5
         LB,RW    INPUT,RC
         CI,RW    C','              CHECK SEPARATOR
         BNE      START1            LOOKS LIKE I NEED PREINIT ALSO
         BDR,RC   %+1                NOW GET REST OF STUFF IN
         LB,R3    INPUT,RC
         BDR,RC   %+1
         LB,R2    INPUT,RC
         SLS,R3   24
         SLD,R2   8
         CI,R2    C'00'             NO DEVICE
         BE       SPILL3             AND NOTHING IN FPT
         CI,R2    C'**'               HOW ABOUT DEFAULT ANYTHING
         BNE      %+2                  NO, USE IT AS IS
         LI,R2    0
         STW,R2   *FPTSLOT
         MTW,1    FPTSLOT           BUMP
         LW,R3    Y4                ASSUME USER IS OK.
         STS,R3   FPT1+1            ADD PRESENCE BIT
SPILL3   BDR,RC   %+1
         LB,RW    INPUT,RC
         CI,RW    C','
         BNE      START1
         BDR,RC   %+1
         LI,RL    LOOP1
         LI,RN    ELOOP1
         LI,RX    1                 ONE DIGIT THIS FIELD
         LI,IN    16                 OF THIS RANGE
         LB,RW    INPUT,RC            GET FIRST DIGIT
LOOP1    CB,RW    TAB1,IN
         BE       HIT               OK GET HEX DIGIT
         BDR,IN   *RL                TIL I FIND IT
         B        START1              OR ERROR OUT
ELOOP1   SLS,R11  -28                  NOW RIGHT JUSTIFY IT
         CI,R11   X'F'              MAXIMUM THIS HANDLES
         BG       START1             FOR NOW
         CI,R11   X'0'              ANY SPECIFIED RBID
         BE       ELOOP1A           NOPE
         CI,R11   X'F'              FOR NOW F MEANS DEFAULT ANY
         CI,R11   X'F'              FOR NOW F MEANS DEFAULT AANY
         BNE      %+2               OTHERWISE USE SPECIFIED
         LI,R11   0
         STW,R11  *FPTSLOT
         LW,R11   Y2
         STS,R11  FPT1+1            ADD PARAMETR BIT
         MTW,1    FPTSLOT           BUMP
         LW,R11   FPT1+1
         CW,R11   Y4
         BAZ      ELOOP1A           NO DEV TYPE TO ADJUST.
         LW,R2    FPT1+3
         SLD,2    -4
         SLS,2    -4
         SLD,2    -4
         LB,2     3
         STW,2    FPT1+3
ELOOP1A  LI,R11   2                 SET UP
         STW,R11  *FPTSLOT          SPILL FUNCTION CODE
         MTW,1    FPTSLOT
         LB,RW    INPUT,RC
         CI,RW    C','
         BNE      START1
         LW,R2    INPUT+4
         LW,R3    INPUT+5
         SLD,R2   16
         CW,R2    =C'0000'
         BE       ELOOP1B           NO FORM NAME SPECIFIED
         CW,R2   =C'****'           DEFAULT ANY FORM NAME
         BNE      %+2                NO, USE SPECIFIED
         LI,R2    0                   USE DEFAULT ANY
         STW,R2   *FPTSLOT
         MTW,1    FPTSLOT           BUMP
         LW,R3    Y001              ADD PARAMETER PRESENT BIT
         STS,R3   FPT1+1             IN CONTROL WORD
ELOOP1B  AI,RC    -5
         LB,RW    INPUT,RC
         CI,RW    C','
         BNE      START1            SYNTAX ERROR
         BDR,RC   %+1
         LI,RL    LOOP3
         LI,RN    ELOOP3
         LI,RX    2                 FIRST FIELD HAS 2 DIGITS
         LB,RW    INPUT,RC          SKIP OVER SEPARATORS
LOOP3    CB,RW    TAB1,IN
         BE       HIT
         BDR,IN   *RL
         B        START1
ELOOP3   SLS,R11  -24
         CI,R11   X'10'
         BE       START1            NO RUNNING JOBS
         CI,R11   X'23'
         BG       START1            TO BIG A NUMBER
         STW,R11  *FPTSLOT
         LI,RL    LOOP4
         LI,RN    ELOOP4
         LI,RX    2                 FIRST FIELD HAS 2 DIGITS
         CB,RW    TAB1              SEPARATOR
         BNE      START1              NOPE
         BDR,RC   %+1
         LB,RW    INPUT,RC          SKIP OVER SEPARATORS
LOOP4    CB,RW    TAB1,IN
         BE       HIT
         BDR,IN   *RL
         B        START1
ELOOP4   SLS,R11  -24
         CI,R11   X'10'
         BE       START1            I SAID NO RUNNING JOBS
         CI,R11   X'23'
         BG       START1            TO BIG
         SLS,R11  8
         OR,R11   *FPTSLOT
         STW,R11  *FPTSLOT          THE PRIORITY IS RIGHT
         MTW,1    FPTSLOT           BUMP
         LI,RL    LOOP5
         LI,RN    ELOOP5
         LI,RX    4                 SYSID HAS 4 DIGITS
         CB,RW    TAB1              SEPARATOR
         BNE      START1              NOPE
         BDR,RC   %+1
         LB,RW    INPUT,RC          SKIP OVER SEPARATORS
LOOP5    CB,RW    TAB1,IN
         BE       HIT
         BDR,IN   *RL
         B        START1
ELOOP5   SLS,R11  -16
         CI,R11   X'0000'           NO SYSID SPECIFIED
         BE       SPILLNOW
         CI,R11   X'FFFF'           DEFAULT DESIRED
         BNE      %+2                NOPE USE AS IS
         LI,R11   X'0000'            ANY SYSID WILL DO.
         STW,R11  *FPTSLOT
         LI,R11   X'800'
         STS,R11  FPT1+1            ADD PRESENCE BIT
         B        SPILLNOW
FILLIT   EQU      %
         LW,R2    INPUT+1
         LW,R3    INPUT+2
         SLD,R2   -16
         LI,R2    4
         SLD,R2   24
         OR,R3    =C'   '
         STW,R2   VLP2+1
         STW,R3   VLP2+2            FILE NAME WE ARE AFTER
FILL1,FPTY,VLP2 ;
         M:OPEN   M:EI,(FILE,'FILE'),(ERR,FILE2E),(ABN,FILE2A),;
                  (IN),(CONSEC),(BUF,INBUF)
FILL2    M:READ   M:EI,(BUF,WHAT),(SIZE,56)
         LI,R8    C'FI'
FILL3    CAL1,8   WHAT              LETS SEE IF WE GO
         BCS,8    BADFILL
FILL4    M:OPEN   M:SO,(DEVICE,'C2'),(FPARAM,WHAT),(OUT),(ERR,ER1),;
                  (ABN,AB1)
         M:READ   M:EI,(BUF,INBUF),(SIZE,512),(ERR,ER1),(ABN,EOF2)
         LW,R1    M:EI+4
         SLS,R1   -17
         STW,R1   LENGTH2
FILL5    M:WRITE  M:SO,(BUF,INBUF),(SIZE,*LENGTH2),(ERR,ER1),(ABN,AB1)
         B        FILL4+1
EOF2     M:CLOSE  M:SO
         M:CLOSE  M:EI
         LI,8     C'FI'
         M:LDEV   'C2',ASAVE
         BCS,8    CLOSEBAD          PROBABLY OUT OF SLOTS
         LH,R7    SR1               GET SLOTS LEFT
         INT,R7   R7
         BAL,R13  OPEN
         STW,R11  MSG5+10           NEW APROX NUMBER
         LW,R11   WHAT+10            BASED ON THIS
         CI,R11   X'22'             WAS IT NCCTL
         BE       TELLUSOUT         OUTPUT REALLY,
         CI,R11   X'F0'             OR JCL
         BANZ     FILLEOF2           NOPE, ALL THE SAME
TELLUS   EQU      %
         LW,R7    SR1                IF INPUT GOT NEW SYSID
         BAL,R13  OPEN
         STW,R11  MSG5+7            INFORM CALLER
         LW,R11   =C' IN '
TELLUS2  STW,R11  MSG5+11
         LW,R7    WHAT+13           GET OLD SYSID
         BAL,R13  OPEN
         STW,R11  MSG5+3
         B        FILLEOF3
TELLUSOUT EQU     %
         LW,R7    SR1               ALSO GOT NEW SYSID
         BAL,R13  OPEN               EXPAND THIS DATA
         STW,R11  MSG5+7
         LW,R11   =C' OUT'
         B        TELLUS2
FILLEOF2 LW,R7    WHAT+13           GET OLD SYSID
         BAL,R13  OPEN
         LW,R10   =C' OUT'
         STW,R10  MSG5+11
         STW,R11  MSG5+3
         STW,R11  MSG5+7
FILLEOF3 M:WRITE  M:LO,(BUF,MSG5),(SIZE,60)
         B        START1
CLOSEBAD M:WRITE  M:LO,(BUF,MSG8),(SIZE,44)
         B        START1
FILE2E   DATA     0
FILE2A   M:WRITE  M:LO,(BUF,MSG3),(SIZE,32)
         B        START1
HIT      CB,RW    TAB1              WAS IT A ,
         BE       START1              GOT DISPLACEMENT ERROR
         LB,R10   TAB2,IN              GET HEX DIGIT
         LI,IN    16                RESET INDEX FOR NEXT GUY
         SLD,R10  -4                    PACKED AWAY
         BDR,RC   %+2               SET UP FOR NEXT DIGIT
         B        *RN                 GOT LAST DIGIT DONE
         LB,RW    INPUT,RC              GET NEXT DIGIT IN
         BDR,RX   *RL                     LOOP IN FIELD
         B        *RN               JUMP TO NEXT FIELD
OPEN     LI,15    8
         LI,10    0
         LI,11    0
OPENA    LI,6     0
         SLD,6    4                 SLIDE CHARACTERS
         LB,5     TABA,6             TRANSLATE
         STB,5    11                  STUFF
         SCD,10   8                    PACK
         BDR,15   OPENA                 ALL OF THEM
         SCD,10   -X'20'            ADJUST THEM
         B        *13                 AND RETURN
CHKCAR   LI,R2    0
         SLD,R2   8
         CI,R2    C' '
         BE       CAROK
         CI,R2    C'A'
         BL       CARNOK
         CI,R2    C'I'
         BLE      CAROK
         CI,R2    C'J'
         BL       CARNOK
         CI,R2    C'R'
         BLE      CAROK
         CI,R2    C'S'
         BL       CARNOK
         CI,R2    C'Z'
         BLE      CAROK
         CI,R2    C'0'
         BL       CARNOK
         CI,R2    C'9'
         BLE      CAROK
CARNOK   BAL,R13  OPEN
         B        0,1               DOUBLE STORE
CAROK    BDR,R4   CHKCAR
         LW,R11   R7
         B        1,R1              SINGLE STORE
SPILLNOW EQU      %
SP1,FPTZ,VLP3 ;
         M:OPEN   M:EO,(FILE,'FILE'),(ERR,FILE1E),(ABN,S1B),;
                  (IN),(CONSEC)
         M:KEYIN  (MESS,MSG2),(REPLY,CHECK),(SIZE,1),(ECB,JUNK)
         LI,1     1
         LB,2     CHECK,1
         CI,R2    C'Y'
         BE       S1A               OVERWRITE FILE
         M:CLOSE  M:EO,(SAVE)
         B        START1            TRY AGAIN
S1A      M:CLOSE  M:EO,(SAVE)
S1B      EQU      %
S1,FPTX,VLP1 ;
         M:OPEN   M:EO,(FILE,'FILE'),(ERR,FILE1E),(ABN,STOPIT),;
                  (SAVE),(OUTIN),(CONSEC)
         LI,R8    C'SP'
         CAL1,8   FPT1              LETS START
         BCS,8    BADSPILL
S2       M:OPEN   M:SI,(DEVICE,'C2'),(FPARAM,WHAT),(ABN,NOFILE),;
                  (ERR,ER1)
PRINTFPT EQU      %
         LI,R1    S3                NEXT PLACE TO GO
PRINT1   STW,R1   VECTOR
         LI,R1    15                CLEAR TABLE
         LW,R2    =C'    '
         STW,R2   MSG13-1,R1        TO BLANKS
         LW,R7    WHAT+13           GET SYSID
         BAL,R13  OPEN
         STW,R11  MSG13
         LW,R7    WHAT+3            GET DEVICE CODE
         INT,R7   R7
         OR,R7    =X'40400000'
         LI,R4    4
         LW,R3    R7
         BAL,R1   CHKCAR            PRINTABLE
         STW,R10  MSG13+2           GARBAGE HERE
         STW,R11  MSG13+2            RIGHT EITHER WAY.
         LW,R7    WHAT+4            GET RBID
         BAL,R13  OPEN
         SLS,R11  16
         SLS,R11  -8
         OR,R11   =X'40000040'
         STW,R11  MSG13+3
         LW,R7    WHAT+6            JDE
         BAL,R13  OPEN
         SLS,R11  16
         SLS,R11  -8
         OR,R11   =X'40000040'
         STW,R11  MSG13+4
         LW,R7    WHAT+7            COPIES
         BAL,R13  OPEN
         SLS,R11  16
         SLS,R11  -8
         OR,R11   =X'40000040'
         STW,R11  MSG13+5
         LW,R7    WHAT+8            FPC NAME
         BEZ      %+4
         BAL,R13  OPEN
         STW,R10  MSG13+6
         STW,R11  MSG13+7
         LI,R4    4
         LW,R7    WHAT+9            FORM NAME SPECIFIED
         BEZ      %+5               DO NOT PRINT 0'S
         LW,R3    R7
         BAL,R1   CHKCAR
         STW,R10  MSG13+8
         STW,R11  MSG13+9
         LW,R7    WHAT+10
         BAL,R13  OPEN
         SLS,R11  16
         SLS,R11  -8
         OR,R11   =X'40000040'
         STW,R11  MSG13+12
         LW,R7    WHAT+11
         BAL,R13  OPEN
         STW,R10  MSG13+10
         STW,R11  MSG13+11
         LW,R7    WHAT+12
         BAL,R13  OPEN
         STW,R10  MSG13+13
         STW,R11  MSG13+14
         M:WRITE  M:LO,(BUF,MSG13),(SIZE,80)
         B        *VECTOR
S3       M:WRITE  M:EO,(BUF,WHAT),(SIZE,56),(ERR,ER1),(ABN,AB1)
S4       M:READ   M:SI,(BUF,BUFFER),(SIZE,512),(ABN,SPILLEOF)
         LW,R1    M:SI+4
         SLS,1    -17               ADJUSTED
         STW,1    LENGTH
S5       M:WRITE  M:EO,(BUF,BUFFER),(SIZE,*LENGTH),(ABN,AB2),;
                  (ERR,ER2)
         B        S4
BADFILL  M:WRITE  M:LO,(BUF,MSG6),(SIZE,32)
         M:CLOSE  M:EI
         LI,R1    START1
         B        PRINT1            PUT OUT FPT
BADSPILL M:WRITE  M:LO,(BUF,MSG7),(SIZE,40)
         M:CLOSE  M:EO
         B        START1
EXIT     M:EXIT
NOFILE   M:CLOSE  M:EO
         M:WRITE  M:LO,(BUF,MSG10),(SIZE,36)
         B        START1
         B        START1
ER1      DATA     1
         DATA     0
AB1      DATA     2
         DATA     0
ER2      DATA     3
         DATA     3
AB2      DATA     4
         DATA     4
FILE1E   DATA     0
SPILLEOF EQU      %
         M:CLOSE  M:SI,(SAVE)
         M:CLOSE  M:EO,(SAVE)
,TYC     M:LDEV   'C2',ASAVE
         M:LDEV   'C2'              TO FLUSH STREAM
         LW,R7    TYC+1
         CI,R7    X'40'
         BANZ     UGOTIT
         M:WRITE  M:LO,(BUF,MSG11),(SIZE,36)
         B        START1
UGOTIT   EQU      %
         LW,R7    WHAT+13           GET SYSID
         BAL,R13  OPEN
         STW,R11  MSG12+2
         M:WRITE  M:LO,(BUF,MSG12),(SIZE,64)
         B        START1
STOPIT   M:CLOSE  M:EO
HELPIT   EQU      %
         LI,R1    FPT1-MSGBASE-2    NUMBER OF MESSAGES
         LW,R2    MSGBASE,R1        TABLE OF MESSAGES
         LB,R4    *R2               GET BYTE COUNT
         M:WRITE  M:LO,(BUF,*2),(BTD,1),(SIZE,*4)
         BDR,R1   HELPIT+1          DUMP EM OUT
         B        START1
MSGBASE  DATA     0
          DATA      WA(HELP25)
          DATA      WA(HELP24)
          DATA      WA(HELP23)
          DATA      WA(HELP22)
          DATA      WA(HELP21)
          DATA      WA(HELP20)
          DATA      WA(HELP19)
          DATA      WA(HELP18)
         DATA     WA(HELP17)
         DATA     WA(HELP16)
         DATA     WA(HELP15)
         DATA     WA(HELP14)
         DATA      WA(HELP13)
         DATA      WA(HELP12)
         DATA      WA(HELP11)
         DATA      WA(HELP10)
         DATA      WA(HELP9)
         DATA      WA(HELP8)
         DATA      WA(HELP7)
         DATA      WA(HELP6)
         DATA      WA(HELP5)
         DATA      WA(HELP4)
         DATA      WA(HELP3)
         DATA      WA(HELP2)
         DATA      WA(HELP1)
         B        START1
FPT1     DATA     X'1A000000'
         DATA     X'B0180800'
         DATA     C'C2'
         DATA     0
         DATA     2
         DATA     X'0'
         DATA     X'0707'
         DATA     X'51'
         RES      10
FPT2     RES      20
*
         DATA     0
WHAT     RES      20
LENGTH   DATA     0
LENGTH2  DATA     0
HELP1 TEXTC 'ENTER SPILL,####,%%,%%,;;;;,{,%%,&&&&,@*  OR'
HELP2 TEXTC 'FILL,&&&&(C/R) DECODED AS FOLLOWS'
HELP3 TEXTC ' @* - D(C/R) - DELETE, - S(C/R) - SAVE. -A(C/R) AUTO'
HELP4 TEXTC ' &&&& IS SAVE ON FILE NAME IN RUNNING ACCOUNT '
HELP5 TEXTC ' { IS ORIGIN . - 0 - LOCAL, 1-E THAT RBID, F ANY RBID'
HELP6 TEXTC ' ;;;; FORM NAME WANTED, **** ANY FORM NAME'
HELP7 TEXTC ' %%  DEVICE NEUMONIC OR CODE OR ** DO NOT CARE'
HELP8 TEXTC ' ####  IS SYSID 0000 THRU 5B5B OR FFFF ANY SYSID'
HELP9 TEXTC ' %%,%% IS LOW SELECTION THRU HIGH SELECTION I.E.'
HELP10 TEXTC ' 00,0F  WAITING JCL FILES PRIO 0 THRU F'
HELP11 TEXTC ' 11,20  WAITING OUTPUT FILES PRIO 0 THRU F'
HELP12 TEXTC ' 21,21  GETS MESSAGE FILES, I.E. DISPLAYS '
HELP13 TEXTC ' 22,22  WAITING NCCTL FILES !!NCTL '
HELP14 TEXTC '  ALL FIELDS MUST BE COMPLETE. BLANKS ARE LEGAL.'
HELP15 TEXTC ' ZEROES IN MOST FIELDS SAYS IGNORE THAT FIELD'
HELP16 TEXTC ' SNAKE WILL GIVE YOU THE FPT  , STATUS ON THE'
HELP17 TEXTC ' NUMBER OF INFILE/OUTFILE SLOTS LEFT (APROX)'
HELP18 TEXTC ' TELLS U IF SYSID HAS CHANGED I.E. OLD NEW '
HELP19 TEXTC ' HAS VARIOUS CHOICES FOR U WHICH ARE USUALLY'
HELP20 TEXTC ' OBVIOUS.  STRONGLY RECCOMMEND ONB BE SET TO'
HELP21 TEXTC ' 0 WHEN MESSING WITH JCL FILES. ESPECIALLY'
HELP22 TEXTC ' WHEN PRIORITIES HAVE BEEN CHANGED BY OPERATOR'
HELP23 TEXTC ' KEYINS. IF ACCOUNT AND ORDER ARE IMPORTANT'
HELP24 TEXTC ' SPILL ALL THOSE JOBS IN SEQUENCE IF OPERATING'
HELP25 TEXTC ' IN THE SAVE MODE.'
MSG1     TEXTC    'ENTER COMMAND OR TYPE HELP     '
         ORG      MSG1+7
CART     DATA     X'03155C0D'
MSG2     TEXTC    'SAVE ON FILE EXISTS. OVERWRITE?? Y OR N  '
         ORG      MSG2+10
         DATA     X'03155C0D'
MSG3     TEXT     'YOUR INPUT FILE DOES NOT EXIST'
MSG5     TEXT ;
 ' OLD SYSID       NEW SYSID       APROX           SLOTS LEFT'
*
MSG6     TEXT     ' MALFORMED FPT HANDED TO SYSTEM'
MSG7     TEXT     ' YOU CAN NOT HAVE WHAT YOU ASKED FOR'
MSG8     TEXT     ' INSUFFICIENT SYMBIONT SPACE REQUEST DENIED'
TAB1     TEXT     ',0123456789ABCDEF^^^'
MSG10    TEXTC    'NOTHING IN RANGE SPECIFIED EXISTS'
MSG11 TEXT  ' BOTH U AND RBBAT NOW HAVE THAT FILE'
MSG12 TEXT  'SYSID        IS YOUR RESPONSIBILITY. RBBAT OBEYED U. '
MSG13    TEXT ;
 '                                                           '
 TEXT ' RBBAT FORGETS THIS'
TAB2     DATA     X'00000102',X'03040506',X'0708090A'
         DATA     X'0B0C0D0E',X'0F000000'
TABA     TEXT     '0123456789ABCDEF' TRANSLATE TABLE
FPTSLOT  DATA     0                 POINTS TO NEXT ENTRY,
BASEFPT1 DATA     X'90080000'       BASIC SPILL FPT
Y4       DATA     X'40000000'
Y2       DATA     X'20000000'
Y001     DATA     X'00100000'
SPFLG    DATA     0                 ADD ZEROED FLAGS HERE
VECTOR   DATA     0
CHECK    DATA     0
AUTO     DATA     0                 MODE OF OPERATION
JUNK     DATA     0                 JUNK WORD
INPUT    RES      40                FOR EXPANSION.
SPFLGEND DATA     0                 END OF ZEROED DATA SECTION.
NXTCR    EQU      %                 FUNNY TABLE
X SET S:UT('0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ')
I DO NUM(X)-1
 ORG BA(NXTCR)+X(I)
 DATA,1 +X(I+1)
         FIN
         BOUND    8
BUFFER   RES      512
INBUF    RES      512
         BOUND    8
PATCH    EQU      %
         LIST     0
         DO1      50
         DATA     0
         LIST     1
         END      START1
