*                                                                       ELS30001
*                                                                       ELS30002
*                                                                       ELS30003
 TITLE 'CP-V/CP-R SUMMARY MODULE ELLA. 708006-A01  6.10.75 '            ELS30004
         SYSTEM   SIG7FDP                                               ELS30005
         CSECT                                                          ELS30006
         DEF      SUM:0                                                 ELS30007
         PAGE                                                           ELS30008
         REF      L:SPACE                                               ELS30009
         REF      L:SPACE2,L:SPACE3                                     S3--0002
         REF      L:PRINT,E:PRINT                                       ELS30010
         REF      TYPEF,:TYPE:,DEVF,:DEV:,MODF,:MOD:                    ELS30011
         REF      HEXDEC:,HEXDECE,HEXFIVE,BINEBC                        ELS30012
         REF      HEXEBC,EBCHEX8,EBCHEX1,MS:HMSN,HMSN:MS,JD:MD,MD:JD    ELS30013
         REF      R:COM,READ:ERF                                        ELS30014
         REF      REW:FLAG                                              ELS30015
         REF      HEXTWO,BUFFER                                         ELS30016
         REF      S:SYS                                                 ELS30017
         REF      HEXFOUR                                               ELS30018
         REF      YEAR:1,YEAR:2,DATE:1,DATE:2                           ELS30019
         REF      TIME:1,TIME:2                                         ELS30020
         REF      DSP:                                                  ELS30021
         REF      MOD:EBC                                               ELS30022
         REF      IONDD                                                 ELS30023
         REF      MOS:128
         PAGE                                                           ELS30024
*                                                                       ELS30025
*                                                                       ELS30026
*        BIFSYS *(KEY,*ADDR) . . .                                      ELS30027
*                                                                       ELS30028
*        KEY IS SYSTEM NAME (CPR,CPV,RBM)                               ELS30029
*        ADDR IS BRANCH ADDRESS                                         ELS30030
*        GROUP MAY BE REPEATED FOR MULTIPLE TEST/BRANCHES               ELS30031
*        AFA(I)   INDICATES B IF NOT SYSTEM                             ELS30032
*        AFA(I,2) INDICATES B INDIRECT                                  ELS30033
*                                                                       ELS30034
*                                                                       ELS30035
BIFSYS   CNAME                                                          ELS30036
         PROC                                                           ELS30037
         LOCAL    I,T1                                                  ELS30038
         GEN,8,4,20  X'71',1,S:SYS         CB,1 S:SYS                   ELS30039
I        DO       NUM(AF)                                               ELS30040
T1       SET      SCOR(AF(I,1),RBM,CPR)                                 ELS30041
         DO       T1>0                                                  ELS30042
         GEN,1,7,4,20  AFA(I,2),X'69'-AFA(I),T1,AF(I,2)                 ELS30043
         ELSE                                                           ELS30044
         GEN,1,7,4,20  AFA(I,2),X'68'+AFA(I),3,AF(I,2)                  ELS30045
         FIN                                                            ELS30046
         FIN                                                            ELS30047
         PEND                                                           ELS30048
*                                                                       ELS30049
*                                                                       ELS30050
         PAGE                                                           ELS30051
*                                                                       ELS30052
*                                                                       ELS30053
SUM:0    EQU      %                                                     ELS30054
         LI,14    24                                                    ELS30055
         BAL,15   L:PRINT           PRINT SUMMARY TITLE                 ELS30056
         DATA     SUMTITLE                                              ELS30057
         BAL,15   L:PRINT                                               ELS30058
         DATA     SUMDOT                                                ELS30059
         BAL,15   L:SPACE3                                              S3--0004
         BAL,15   DSP:                                                  ELS30063
         BAL,15   L:SPACE3                                              S3--0006
*                                                                       ELS30067
         LI,4     DATATBL
         STW,4    DATATBLA
         LI,4     -1604                                                 ELS30068
         LW,15    0                                                     ELS30069
         STW,15   DATATBL+1604,4    CLEAR TABLES                        ELS30070
         BIR,4    %-1               LOOP TILL THE END                   ELS30071
*                                                                       ELS30072
         LW,13    YEAR:1                                                ELS30073
         LW,14    YEAR:2                                                ELS30074
         CW,13    14                CK YEAR BOUNDARY                    ELS30075
         BE       CKDATE                                                ELS30076
SETFLG   STW,1    TIMEFLG           SET TIMEFLG                         ELS30077
         B        DATECKD                                               ELS30078
CKDATE   LW,13    DATE:1                                                ELS30079
         LW,14    DATE:2                                                ELS30080
         CW,13    14                CK DATE BOUNDARY                    ELS30081
         BNE      SETFLG                                                ELS30082
         STW,0    TIMEFLG           RESET TIMEFLG                       ELS30083
DATECKD  STW,0    SYRSTFLG          RESET SYSTEM RESET FLG              ELS30084
*                                                                       ELS30085
SUM:1    EQU      %                                                     ELS30086
*                                                                       ELS30087
*                                                                       ELS30088
*                                                                       ELS30089
         LI,4     TTL             NUMBER OF TBL ENTRIES TO CLEAR        S3--0008
         LI,12    0                                                     ELS30091
         STW,12   CNTBL-1,4       CLEAR TBL LOCS                        S3--0010
         BDR,4    %-1                                                   S3--0011
         REF      MOS:QTY,CHIPERRS
         LI,4     5120              SIZE OF CHIPERRS TABLE
         STW,12   CHIPERRS-1,4      ZERO
         BDR,4    %-1
         STW,12   MOS:QTY           INITIALIZE ERROR COUNTER
         STW,1    REW:FLAG          SET REW:FLAG FOR REWIND             ELS30094
         STW,0    IOTBL             INITIALIZE IOTBL                    ELS30095
         STW,0    TCNT              CLEAR TCNT                          ELS30096
         STW,0    FST28                                                 ELS30097
         STW,0    T28FST                                                ELS30098
         STW,0    TCNT28                                                ELS30099
         STW,0    SUMXY                                                 ELS30100
         STW,0    F28                                                   ELS30101
         STW,0    XCNT                                                  ELS30102
         STW,0    SEQFLG                                                ELS30103
         STW,0    SUMX                                                  ELS30104
*                                                                       ELS30105
RETURN   EQU      %                                                     ELS30106
         BAL,15   READ:ERF          READ A RECORD                       ELS30107
         CI,15    1                 IS THIS GOOD RECORD?                ELS30108
         BNE      FIXSUM            END OF RECORD                       ELS30109
         LB,13    BUFFER                                                ELS30110
         CI,13    X'43'             CK TYPE 43
         BNE      %+2
         REF      MOS:RCRD
         BAL,15   MOS:RCRD          CK FOR MOS CORRECTABLES?
         CI,13    X'18'             SYS.STARTUP CK                      ELS30111
         BNE      PAS18                                                 ELS30112
         LB,11    BUFFER,3          FETCH RECOVERY COUNT                ELS30113
         BNEZ     PAS18             NOT INITIAL STARTUP                 ELS30114
         STW,1    SYRSTFLG          SET SYS.RESET FLG                   ELS30115
PAS18    EQU      %                                                     ELS30116
*                                                                       ELS30117
         LB,10    BUFFER            LOAD TYPE CODE TO R10               ELS30118
         CI,10    X'49'                                                 ELS30119
         BE       RETURN            SKIP TYPE 49                        ELS30120
         CB,10    CODETBL           CK TYPE 11                          ELS30121
         BE       PREDEV                                                ELS30122
         CB,10    CODETBL,1         CK TYPE 12                          ELS30123
         BE       PREDEV                                                ELS30124
         CB,10    CODETBL,2         CK TYPE 13                          ELS30125
         BE       PREDEV                                                ELS30126
         CB,10    CODETBL,3         CK TYPE 15                          ELS30127
         BE       PREDEV                                                ELS30128
*                                                                       ELS30129
*                                                                       ELS30130
*                                                                       ELS30131
         LB,13    BUFFER            FETCH TYPE CODE                     ELS30132
         CI,13    X'28'             CK TYPE 28                          ELS30133
         BNE      PASS28                                                ELS30134
         BIFSYS   *(CPV,RETURN)     B IF NOT CPV                        ELS30135
         B        FIX28             MERGE #28 IOADRS TO IOTBL RTN       ELS30136
PASS28   EQU      %                                                     ELS30137
         LI,4     0                 START FROM CODE 17                  ELS30138
LSYSERR  EQU      %                                                     ELS30139
         CI,4     TTLCPR          IS THIS END OF CPR CODES              S3--0013
         BE       CKCPV                                                 ELS30141
         CB,10    CODETBL+1,4       CK SYSTEM ERROR CODE                ELS30142
         BE       SYSCDE            CPR/CPV SYSTEM ERRCDE               ELS30143
         AI,4     1                 ADD 1 TO X4                         ELS30144
         B        LSYSERR           LOOP FOR ALL SYS. ERRORS            ELS30145
*                                                                       ELS30146
LX       EQU      %                                                     ELS30147
         MTW,1    CNTX              ADD 1 TO CNTX                       ELS30148
         B        RETURN                                                ELS30149
*                                                                       ELS30150
CKCPV    EQU      %                                                     ELS30151
         BIFSYS   *(CPV,LX)         B IF NOT CPV                        ELS30152
         LI,5     0                                                     ELS30153
LCPV     EQU      %                                                     ELS30154
         CI,5     TTLCPVO         HAVE WE CHKED ALL CP-V ONLY CODES     S3--0015
         BE       LXX               UNKNOWN TYPE CODE                   ELS30156
         CB,10    CDETBL,5          CK CP-V SYSTEM ERROR CODES          ELS30157
         BE       SYSCDX                                                ELS30158
         AI,5     1                 UPDATE X5                           ELS30159
         B        LCPV                                                  ELS30160
LXX      MTW,1    CNTXX                                                 ELS30161
         B        RETURN                                                ELS30162
*                                                                       ELS30163
SYSCDX   EQU      %                                                     ELS30164
         CB,10    CDETBL+1          SKIP TYPE 1F                        ELS30165
         BE       RETURN                                                ELS30166
         MTW,1    CNTX+1,5                                              ELS30167
         B        RETURN                                                ELS30168
*                                                                       ELS30169
*                                                                       ELS30170
*                                                                       ELS30171
SYSCDE   EQU      %                                                     ELS30172
         CB,10    CODETBL+4,3  SKIP TYPE 16                             ELS30173
         BE       RETURN                                                ELS30174
         CB,10    CODETBL+3,1       SKIP TYPE 32                        ELS30175
         BE       RETURN                                                ELS30176
         MTW,1    CNTBL,4           INCREMENT CNTBL BY 1                ELS30183
         B        RETURN                                                ELS30184
*                                                                       ELS30185
*                                                                       ELS30186
* THIS SECTION MERGE TYPE 28 IOADRS AND IOCNT INTO IOTBL:               ELS30187
*                                                                       ELS30188
FIX28    EQU      %                                                     ELS30189
         STW,1    F28               SET F28 FLAG                        ELS30190
         STW,2    INDXIO                                                ELS30191
         STW,3    INDXCNT                                               ELS30192
         STW,0    WDCNTX                                                ELS30193
RTN28    EQU      %                                                     ELS30194
         LI,5     5                                                     ELS30195
         CW,5     WDCNTX            LAST ENTRY CK                       ELS30196
         BE       PASS28            GO ENTER SYS. ERR. CNT              ELS30197
         LW,6     INDXIO                                                ELS30198
         LW,13    BUFFER,6                                              ELS30199
         CW,13    X40X                                                  S3--0017
         BE       PASS28          DO NOT PROCESS BEYOND END OF LIVE     S3--0018
*                                 X'28' DATA....                        S3--0019
         SLS,13   -16               IOADRS                              ELS30200
         STW,13   DEVNEW            FX DEVNEW                           ELS30201
         LW,6     INDXCNT                                               ELS30202
         LW,13    BUFFER,6          IOCNT                               ELS30203
         STW,13   IOCNTX            WORKING IOCNT                       ELS30204
         MTW,1    WDCNTX                                                ELS30205
         MTW,2    INDXIO            UPDATE FOR NEXT PAIR                ELS30206
         MTW,2    INDXCNT                                               ELS30207
         LW,13    IOCNTX                                                ELS30208
         CW,13    0                                                     ELS30209
         BL       RTN28             CK MINUS I/OCOUNT                   ELS30210
         B        MERGE28           MERGE IOADR TO IOTBL                ELS30211
*                                                                       ELS30212
*                                                                       ELS30213
* THIS SECTION BUILDS IOTBL, MODTBL AND ADDRTBL.                        ELS30214
*                                                                       ELS30215
PREDEV   EQU      %                                                     ELS30216
         LW,13    BUFFER                                                ELS30217
         STW,13   ETYPE             SAVE ERCODE                         ELS30218
         AND,13   XFFFFX                                                ELS30219
         STW,13   MODNEW            NEW MOD NUMBER                      ELS30220
         LI,4     2                                                     ELS30221
         LW,13    BUFFER,4                                              ELS30222
         AND,13   XFFFFX                                                ELS30223
         STW,13   DEVNEW            NEW I/O ADRS                        ELS30224
*                                                                       ELS30225
MERGE28  EQU      %                 MERGE #28 IOADR.                    ELS30226
         LW,13    DATATBLA          ADDR. OF DATATBL                    ELS30227
         STW,13   ADDRTBL           INITIALIZE ADDRTBL                  ELS30228
         LI,4     1                 INITIALIZE X4=1                     ELS30229
         CW,0     IOTBL             CK I/O ADRS COUNT                   ELS30230
         BE       L2                THE FIRST ENTRY                     ELS30231
L1       EQU      %                                                     ELS30232
         LW,13    IOTBL,4                                               ELS30233
         CI,13    0                                                     ELS30234
         BE       L2                                                    ELS30235
         CW,13    DEVNEW            DOES THIS MATCH OLD I/O ADRS?       ELS30236
         BE       L10X                                                  ELS30237
         AI,4     1                 INCREMENT X4 BY 1                   ELS30238
         CI,4     100               CK FOR GT 100 ENTRIES               ELS30239
         BGE      ERMESS1                                               ELS30240
         B        L1                                                    ELS30241
L2       EQU      %                                                     ELS30242
         LW,14    DEVNEW                                                ELS30243
         STW,14   IOTBL,4           ADDING A NEW IOADDR                 ELS30244
         LB,13    BUFFER            CK #28                              ELS30245
         CI,13    X'28'                                                 ELS30246
         BNE      X1                                                    ELS30247
         LW,14    X40X                                                  ELS30248
         STW,14   MODTBL,4                                              ELS30249
         B        X2                                                    ELS30250
X1       EQU      %                                                     ELS30251
         LW,14    MODNEW                                                ELS30252
         STW,14   MODTBL,4          ADDING A NEW MOD. NO.               ELS30253
X2       EQU      %                                                     ELS30254
         MTW,1    IOTBL             INCREMENT IOTBL CNT BY 1            ELS30255
*                                                                       ELS30256
         LW,13    DATATBLA                                              ELS30257
         STW,13   ADDRTBL,4                                             ELS30258
         AI,13    12                12 COL.                             ELS30259
         STW,13   DATATBLA          SAVE FOR NEXT NEW I/O ADRS          ELS30260
L10      LW,13    ADDRTBL,4                                             ELS30261
         STW,13   WORK              SAVE TO WORK AREA                   ELS30262
         LB,13    BUFFER            FETCH TYPECODE                      ELS30263
         CI,13    X'28'             CK TYPE 28                          ELS30264
         BE       FXIOCNT                                               ELS30265
         LI,6     9                                                     ELS30266
         LW,10    BUFFER,6                                              ELS30267
         STW,10   IOCNTX            WORKING IOCNT                       ELS30268
         CB,13    CODETBL           CK 11                               ELS30269
         BE       L11                                                   ELS30270
         CB,13    CODETBL,2         CK TYPE 13                          ELS30271
         BE       L13                                                   ELS30272
         CB,13    CODETBL,3         CK TYPE 15                          ELS30273
         BE       L15                                                   ELS30274
         LW,14    WORK                                                  ELS30275
         AI,14    3                                                     ELS30276
         MTW,1    *14               ADD 1 TO TYPE 12 CNT                ELS30277
         B        FXSUB                                                 ELS30278
*                                                                       ELS30279
L10X     LW,14    MODTBL,4                                              ELS30280
         CW,14    X40X              IS TYPE 28 ENTERED                  ELS30281
         BNE      L10                                                   ELS30282
         LB,13    BUFFER            CK TYPE 28                          ELS30283
         CI,13    X'28'                                                 ELS30284
         BE       L10               TYPE 28                             ELS30285
         LW,14    MODNEW                                                ELS30286
         STW,14   MODTBL,4                                              ELS30287
         B        L10                                                   ELS30288
*                                                                       ELS30289
*                                                                       ELS30290
L11      MTW,1    *WORK             ADD 1 TO TYPE 11 CNT                ELS30291
         B        FXSUB                                                 ELS30292
L13      LW,14    WORK                                                  ELS30293
         AI,14    1                                                     ELS30294
         MTW,1    *14               ADD 1 TO TYPE 13 CNT                ELS30295
         B        FXSUB                                                 ELS30296
L15      LW,14    WORK                                                  ELS30297
         AI,14    2                                                     ELS30298
         MTW,1    *14               ADD 1 TO TYPE 15 CNT                ELS30299
FXSUB    LW,14    WORK                                                  ELS30300
         AI,14    4                                                     ELS30301
         MTW,1    *14                                                   ELS30302
*                                                                       ELS30303
         LB,13    BUFFER                                                ELS30304
         CI,13    X'12'                                                 ELS30305
         BE       FXIOCNT                                               ELS30306
         CI,13    X'15'                                                 ELS30307
         BE       FXIOCNT                                               ELS30308
         B        RETURN            11/13, RETURN                       ELS30309
FXIOCNT  EQU      %                                                     ELS30310
         LB,13    BUFFER                                                ELS30311
         CI,13    X'28'                                                 ELS30312
         BE       SX28                                                  ELS30313
         LI,6     9                                                     ELS30314
         LW,14    BUFFER,6                                              ELS30315
         CW,14    0                                                     ELS30316
         BL       RETURN            MINUS I/O COUNT                     ELS30317
SX28     EQU      %                                                     ELS30318
         LW,14    WORK                                                  ELS30319
         AI,14    5                 ACCESS TIME1                        ELS30320
         LW,13    *14                                                   ELS30321
         CW,13    0                 FIRST TIME CK                       ELS30322
         BNE      PASFST                                                ELS30323
         LW,12    BUFFER,1          FETCH FIRST TIME                    ELS30324
         STW,12   *14               STORE FIRST TIME,TB                 ELS30325
*                                                                       ELS30326
         LW,14    WORK                                                  ELS30327
         AI,14    7                                                     ELS30328
         STW,12   *14               STORE CURR. TIME TC                 ELS30329
*                                                                       ELS30330
         LW,14    WORK                                                  ELS30331
         AI,14    6                                                     ELS30332
         LW,13    IOCNTX                                                ELS30333
         STW,13   *14               STORE FIRST IOCNT, CB               ELS30334
*                                                                       ELS30335
         LW,14    WORK                                                  ELS30336
         AI,14    8                                                     ELS30337
         STW,13   *14               STORE CURR. IOCNT,CC                ELS30338
*                                                                       ELS30339
CK28X    EQU      %                                                     ELS30340
         LB,13    BUFFER                                                ELS30341
         CI,13    X'28'                                                 ELS30342
         BE       RTN28             RETURN TO FIX28 ROUTINE             ELS30343
         B        RETURN                                                ELS30344
*                                                                       ELS30345
PASFST   EQU      %                                                     ELS30346
         LW,13    SYRSTFLG                                              ELS30347
         CW,13    0                                                     ELS30348
         BE       PAS1              SYSTEM RESET FLG ON                 ELS30349
         STW,0    SYRSTFLG          RESET FLG                           ELS30350
         LW,14    WORK                                                  ELS30351
         AI,14    6                 CB                                  ELS30352
         STW,0    *14               CB=0                                ELS30353
*                                                                       ELS30354
         LW,14    WORK                                                  ELS30355
         AI,14    9                                                     ELS30356
         LW,13    *14               CT                                  ELS30357
*                                                                       ELS30358
         LW,14    WORK                                                  ELS30359
         AI,14    10                                                    ELS30360
         LW,12    *14               DELT                                ELS30361
         AW,12    13                CT+DELTA                            ELS30362
*                                                                       ELS30363
         LW,14    WORK                                                  ELS30364
         AI,14    9                                                     ELS30365
         STW,12   *14               STORE CT                            ELS30366
PAS1     LW,14    WORK                                                  ELS30367
         AI,14    6                                                     ELS30368
         LW,13    *14               FETCH CB                            ELS30369
         LW,14    WORK                                                  ELS30370
         AI,14    8                                                     ELS30371
         LW,12    IOCNTX            FETCH CURR. IOCNT                   ELS30372
         STW,12   *14               STORE CC                            ELS30373
         LW,12    *14               FETCH CC                            ELS30374
         SW,12    13                                                    ELS30375
         LW,14    WORK                                                  ELS30376
         AI,14    10                                                    ELS30377
         STW,12   *14               STORE DELTA                         ELS30378
*                                                                       ELS30379
         LW,14    WORK                                                  ELS30380
         AI,14    7                                                     ELS30381
         LW,13    BUFFER,1                                              ELS30382
         STW,13   *14               UPDATE TC                           ELS30383
*                                                                       ELS30384
         B        CK28X                                                 ELS30385
ERMESS1  LI,14    40                                                    ELS30386
         BAL,15   E:PRINT           ERROR MESSAGE                       ELS30387
         DATA     ERRMESS1                                              ELS30388
         B        R:COM             READ ANOTHER CARD                   ELS30389
*                                                                       ELS30390
*                                                                       ELS30391
         PAGE                                                           ELS30392
*                                                                       ELS30393
*                                                                       ELS30394
* THIS SECTION PRINTS OUT SYSTEM ERRORS.                                ELS30395
*                                                                       ELS30396
*                                                                       ELS30397
FIXSUM   EQU      %                                                     ELS30398
*                                                                       ELS30399
*  CLEAR IO ACTIVITY COUNT BECAUSE IT IS NOT TO BE                      ELS30400
*  PRINTED.. IF IN THE FUTURE,IO ACTIVITY IS DESIRED,                   ELS30401
*  SIMPLY DELETE THE INSTRUCTION BELOW.....                             ELS30402
*                                                                       ELS30403
*                                                                       ELS30404
         STW,0    CNTX+8       CLEAR IO ACTIVITY COUNT.                 ELS30405
*                                                                       ELS30406
*                                                                       ELS30407
         LW,11    CNTBL+1           SAVE CNTBL+1(CNT18)                 ELS30408
         LW,12    DEVF              CHECK DEVICE FLAG                   ELS30409
         BEZ      PAS18Y                                                ELS30410
         STW,0    CNTBL+1           CLEAR CNT18                         ELS30411
PAS18Y   LW,12    MODF              CHECK MODEL FLAG                    ELS30412
         BEZ      PAS18Z                                                ELS30413
         STW,0    CNTBL+1           CLEAR CNT18                         ELS30414
PAS18Z   EQU      %                                                     ELS30415
         LW,12    TYPEF                                                 ELS30416
         BEZ      PAS18X                                                ELS30417
         LW,4     CNTBL+1           FETCH SYSTEM RESET COUNT            ELS30418
         BEZ      PAS18X            B: NOT EQYUAL TO ZERO               ELS30419
         LI,4     0                                                     ELS30420
LP1      CI,4     5                                                     ELS30421
         BE       MASK18            NO TYPE18 ENTERED                   ELS30422
         LW,13    :TYPE:,4                                              ELS30423
         CI,13    X'18'                                                 ELS30424
         BE       PAS18X                                                ELS30425
         AI,4     1                                                     ELS30426
         B        LP1                                                   ELS30427
MASK18   EQU      %                                                     ELS30428
         STW,0    CNTBL+1           CLEAR CNT18                         ELS30429
PAS18X   EQU      %                                                     ELS30430
         LI,14    13                                                    ELS30431
*                                                                       ELS30432
         STW,0    SUMX                                                  ELS30433
         LI,13    0                                                     ELS30434
         LI,4     0                 CLEAR X4                            ELS30435
         LI,5     0                 CLEAR X5                            ELS30436
         LI,6     0                 CLEAR X6                            ELS30437
LFIXSUM  AI,6     6                 ADD 6  TO X6                        ELS30438
         CI,4     TTLCPR+1        CK FOR END OF CPR CODES               S3--0021
         BGE      CHKCPV                                                ELS30440
LPX      EQU      %                                                     ELS30441
         LW,10    SUMX                                                  ELS30442
         AW,10    CNTBL,4           ACCUMULATE SUM IN R10               ELS30443
         STW,10   SUMX              SAVE R10                            ELS30444
         LW,14    CNTBL,4           LOAD CNTBL TO R14                   ELS30445
         BEZ      RETRY        NO ENTRY FOR THIS COCE.....              ELS30446
         LW,11    XCNT         ANY ENTRYES.                             ELS30447
         BNEZ     NOPR                                                  ELS30448
         LI,14    13           SET INDEX                                ELS30449
         BAL,15   L:PRINT                                               ELS30450
         DATA     SYSERR                                                ELS30451
         BAL,15   L:SPACE                                               ELS30452
         LI,14    28                                                    ELS30453
         BAL,15   L:PRINT                                               ELS30454
         DATA     TYPEERR                                               ELS30455
         MTW,1    XCNT                                                  ELS30456
NOPR     EQU      %                                                     ELS30457
         LW,14    CNTBL,4      FETCH THE COUNT OF THE TYPE....          ELS30458
         LW,11    SYSTLA                                                ELS30459
         AW,11    6                                                     ELS30460
         STW,11   DATAHEX2                                              ELS30461
         LI,13    0                                                     ELS30462
         BAL,15   HEXFOUR      CONVERT TO DEC. EBC...4 DIGITS           ELS30463
DATAHEX2 DATA     0                 TO BE UPDATED EACH TIME             ELS30464
         LI,12    4            SET THE COUNT FOR ZERO SUPRESSION        ELS30465
         LW,14    DATAHEX2     FETCH THE ADDRESS.                       ELS30466
         BAL,15   SUPZR        SUPRESS LEADING ZEROES.                  ELS30467
         AI,6     1                 INCREMENT X6 BY 1                   ELS30468
         LW,11    SYSTLA                                                ELS30469
         AW,11    5                                                     ELS30470
         STW,11   OUTPUT            PREFIX PRINT BUFFER ADDR.           ELS30471
         AI,5     7                 ADD X5 BY 7, ADJUST NEW LINE        ELS30472
         CI,4     TTLCPR          CK FOR CPR 'UNKNOWN CODE' ENTRY       S3--0023
         BE       CKX                                                   ELS30474
OKX      EQU      %                                                     ELS30475
         LI,14    28                                                    ELS30476
         BAL,15   L:PRINT                                               ELS30477
OUTPUT   DATA     0                 TO BE FIXED FOR EACH PRINT          ELS30478
         AI,4     1                                                     ELS30479
         B        LFIXSUM                                               ELS30480
*                                                                       ELS30481
CKX      RES      0                                                     ELS30482
         BIFSYS   *(CPV,OKX)        B IF NOT CPV                        ELS30483
RETRY    EQU      %                                                     ELS30484
         AI,4     1                                                     ELS30485
         AI,6     1                                                     ELS30486
         AI,5     7                                                     ELS30487
*                                                                       ELS30488
         B        LFIXSUM                                               ELS30489
CHKCPV   EQU      %                                                     ELS30490
         BIFSYS   *(CPV,FIXTOTAL)   B IF NOT CPV                        ELS30491
         CI,4     TTL-2           HAVE WE CHKED ALL CPR/CPV CODES       S3--0025
         BGE      FIXTOTAL     BRANCH ALL SYSTEM ERRORS DONE            ELS30493
         B        LPX                                                   ELS30494
*                                                                       ELS30495
*                                                                       ELS30496
FIXTOTAL BAL,15   IOCNTFX           END OF SYS. ERR., GO FIX IOCNT      ELS30497
         PAGE                                                           ELS30498
*                                                                       ELS30499
*                                                                       ELS30500
* THIS SECTION OUTPUTS DEVICE ERRORS AND TOTAL ERRORS.                  ELS30501
*                                                                       ELS30502
*                                                                       ELS30503
FXDEVSUM EQU      %                                                     ELS30504
*                                   START PRINT OUT DATA LINES BELOW:   ELS30505
*                                                                       ELS30506
         LW,14    IOTBL             GET IOTBL NO. OF ENTRY              ELS30507
         CI,14    0                                                     ELS30508
         BE       MOS:SUM           NO ENTRY
         AI,14    1                 READJUST ENTRYCNT                   ELS30510
         STW,14   ENTRYCNT          SAVE ENTRY COUNT                    ELS30511
*                                                                       ELS30512
         LI,7     1                 X7=1                                ELS30513
         BAL,15   FXINDX4           SORT IOTBL RTN                      ELS30514
*                                                                       ELS30515
LOOPOUT  LW,15    X40X                                                  ELS30516
         LI,5     -44                                                   ELS30517
         STW,15   OUTBUFF+44,5      MOVE IN SPACE                       ELS30518
         BIR,5    %-1                                                   ELS30519
*                                                                       ELS30520
         CW,7     ENTRYCNT                                              ELS30521
         BE       MOS:SUM
*                                                                       ELS30523
         LW,4     IOTBLX,7                                              ELS30524
         SLS,4    -24                                                   ELS30525
         LW,11    IOTBL,4           LOAD FST I/O ADDR.                  ELS30526
         STW,11   DEVNUM            SAVE DEV.NO.                        ELS30527
DEV10    EQU      %                                                     ELS30528
         LW,14    DEVNUM                                                ELS30529
         BAL,15   IONDD             RESULT IN R14 AND R15               ELS30530
         STH,15   OUTBUFF+2         STORE THE LOWER HALF WORD           ELS30531
         SLS,15   -16               SHIFT 16 BITS TO RIGHT              ELS30532
         STB,15   OUTBUFF+1,3                                           ELS30533
*                                   CK MDL BELOW:                       ELS30534
*                                                                       ELS30535
         LW,11    MODTBL,4                                              ELS30536
         STW,11   MODNUM                                                ELS30537
*                                                                       ELS30538
MOD10    EQU      %                                                     ELS30539
         LW,14    MODNUM                                                ELS30540
         CW,14    X40X              IS MODEL NO.=0(40)                  ELS30541
         BE       LOOPLP            DON'T PRINT OUT                     ELS30542
         BAL,15   MOD:EBC                                               ELS30543
         STW,15   OUTBUFF                                               ELS30544
*                                 GET PTR INTO DATATBL                  S3--0027
         LW,10    ADDRTBL,4                                             ELS30546
         STW,10   WORK                                                  ELS30547
         LI,13    0                                                     ELS30548
*                                 GET #11 ENTRIES (SIO FAILURES)        S3--0029
         LW,14    *WORK             ACCESS 11                           ELS30549
         STW,14   SUM11                                                 ELS30550
         BAL,15   HEXFIVE                                               ELS30551
         DATA     OUTBUFF+3                                             ELS30552
*                                                                       ELS30553
         LW,14    %-1          FETCH THE CURRENT ADDRESS.               ELS30554
         LI,12    5            SET THE COUNT                            ELS30555
         BAL,15   SUPZR        SUPRES LEADING ZEROES.                   ELS30556
A13      EQU      %                                                     ELS30557
         LW,13    WORK                                                  ELS30558
         AI,13    1                                                     ELS30559
*                                 GET #13 ENTRIES (UNEXP INTS)          S3--0031
         LW,14    *13                                                   ELS30560
         STW,14   SUM13                                                 ELS30561
         LI,13    3                                                     ELS30562
         BAL,15   HEXFIVE                                               ELS30563
         DATA     OUTBUFF+4                                             ELS30564
         LW,14    %-1          FETCH CURRENT ADDRESS.                   ELS30565
         LI,12    5            SET COUNT                                ELS30566
         BAL,15   SUPZR        SUPRESS LEADING ZEROES.                  ELS30567
A15      EQU      %                                                     ELS30568
         LW,13    WORK                                                  ELS30569
         AI,13    2                                                     ELS30570
*                                 GET #15 ENTRIES (DEV ERRORS)          S3--0033
         LW,14    *13               ACCESS 15                           ELS30571
         STW,14   SUM15                                                 ELS30572
         LI,13    3                                                     ELS30573
         BAL,15   HEXFIVE                                               ELS30574
         DATA     OUTBUFF+6                                             ELS30575
         LW,14    %-1                                                   ELS30576
         LI,12    5                                                     ELS30577
         BAL,15   SUPZR                                                 ELS30578
A12      EQU      %                                                     ELS30579
         LW,13    WORK                                                  ELS30580
         AI,13    3                                                     ELS30581
*                                 GET #12 ENTRIES (DEV TIMEOUTS)        S3--0035
         LW,14    *13                                                   ELS30582
         STW,14   SUM12                                                 ELS30583
         LI,13    2                                                     ELS30584
         BAL,15   HEXFIVE                                               ELS30585
         DATA     OUTBUFF+8                                             ELS30586
         LW,14    %-1                                                   ELS30587
         LI,12    5                                                     ELS30588
         BAL,15   SUPZR        SUPRESS LEADING ZEROES.                  ELS30589
*                                                                       ELS30590
*                                                                       ELS30591
TYPEF0   LW,13    WORK                                                  ELS30592
         AI,13    4                                                     ELS30593
         LW,14    *13                                                   ELS30594
         CI,14    0                                                     ELS30595
         BE       LOOPLP                                                ELS30596
         AWM,14   SUMXY             TOTAL                               ELS30597
*                                                                       ELS30598
LPASS    EQU      %                                                     ELS30599
         LI,13    3                                                     ELS30600
         STW,0    PATCH        RESET PATCH                              ELS30601
         LW,12    WORK                                                  ELS30602
         AI,12    11                ACCESS IOCNT ENTRY                  ELS30603
*                                 GET DEV I/O ACTIVITY                  S3--0037
         LW,14    *12                                                   ELS30604
         CW,14    STARS                                                 ELS30605
         BNE      NOSTAR                                                ELS30606
         LW,14    STARS                                                 ELS30607
         LW,13    STARS+1                                               ELS30608
         LW,12    STARS+2                                               ELS30609
         STW,14   OUTBUFF+10                                            ELS30610
         STW,13   OUTBUFF+11                                            ELS30611
         STW,12   OUTBUFF+12                                            ELS30612
         LW,13    STARS+3                                               ELS30613
         STW,13   OUTBUFF+13                                            ELS30614
         B        TITLCK                                                ELS30615
NOSTAR   EQU      %                                                     ELS30616
         STW,0    STARF             RESET STARF                         ELS30617
         CI,14    0            LESS THAN ZERO                           ELS30618
         BGE      %+3                                                   ELS30619
         LCW,14   14           GET 2'S COMPLEMENT                       ELS30620
         STW,1    PATCH                                                 ELS30621
         BAL,15   HEXDECE                                               ELS30622
         DATA     OUTBUFF+10                                            ELS30623
*                                                                       ELS30624
TITLCK   EQU      %                                                     ELS30625
         LW,13    PATCH                                                 ELS30626
         BEZ      %+3                                                   ELS30627
*                                 LOAD CHAR 'N' IF I/O CNT IS NEG---    S3--0039
*                                 2'S COMPLIMENT WITH 'N' WILL BE LISTEDS3--0040
         LI,13    X'D5'                                                 ELS30628
         STB,13   OUTBUFF+10,2                                          ELS30629
         LW,13    SEQFLG                                                ELS30630
         BNEZ     NOTITL                                                ELS30631
         BAL,15   L:SPACE3                                              S3--0042
         LI,14    13                                                    ELS30635
         BAL,15   L:PRINT           PRINT TITLES                        ELS30636
         DATA     DEVERR                                                ELS30637
         BAL,15   L:SPACE                                               ELS30638
         LI,14    46                                                    ELS30639
         BAL,15   L:PRINT                                               ELS30640
         DATA     DEVT:1                                                ELS30641
         LI,14    51                                                    ELS30642
         BAL,15   L:PRINT                                               ELS30643
         DATA     DEVT:2                                                ELS30644
         STW,1    SEQFLG                                                ELS30645
NOTITL   EQU      %                                                     ELS30646
*                                                                       ELS30647
*                                                                       ELS30648
         LI,14    53                                                    ELS30649
         BAL,15   L:PRINT           PRINT A LINE                        ELS30650
         DATA     OUTBUFF                                               ELS30651
LOOPLP   EQU      %                                                     ELS30652
         AI,4     1                                                     ELS30653
         AI,7     1                                                     ELS30654
         B        LOOPOUT           LOOP TILL ALL DEV. ERR. PRINTED OUT ELS30655
         PAGE
MOS:SUM  EQU      %
         MTW,0    MOS:QTY           ANY MOS CORRECTABLES?
         BEZ      TOTAL             NONE RECORDED
         LCI      0
         STM,0    MOS:SAVE          SAVE REGISTER BLOCK
         BAL,15   L:SPACE2          SKIP 2
         LI,14    22
         BAL,15   L:PRINT           OUTPUT HEADING 1
         DATA     MOS:MSG0
         BAL,15   L:SPACE           SKIP 1
         LI,14    20
         BAL,15   L:PRINT           OUTPUT HEADING 2
         DATA     MOS:MSG2
         LI,13    0                 RESET ERROR INDICATOR
         LI,4     BA(MOS:MSG3)+3    BANK NO. DISPLACEMENT
         LI,2     X'C0'             BANK SEED
         STB,2    0,4               PLANT
         LI,1     4                 4 BANKS/UNIT
NXT:BANK LI,4     BA(MOS:MSG3)+6    POINTER FOR ERRORS THIS BANK
         LI,2     2                 2 UNITS
SUM:BANK BAL,7    BANK:SUM          SUM ERRORS FOR UNIT/BANK
         MTW,1    13                RETURN HERE IF ERRORS
         LI,5     6                 MAX ERRORS REQUIRE 6 DIGITS
         REF      BIN:DEC
         BAL,7    BIN:DEC           CONVERT TO DECIMAL AND STORE
         AI,4     2                 INCREMENT TO UNIT 1 POSITION
         BDR,2    SUM:BANK          SUM ERRORS FOR UNIT 0
         MTW,1    MOS:MSG3          BUMP BANK SEED
         MTW,0    13                TEST LINE ERROR INDICATOR
         BEZ      MOS:NOER          B - IF NO ERROR THIS LINE
         LI,4     22
         LI,14    20
         BAL,15   L:PRINT           OUTPUT ERROR LINE
         DATA     MOS:MSG3
MOS:NOER LI,13    0                 RESET LINE ERROR INDICATOR
         BDR,1    NXT:BANK          DO NEXT BANK
         LCI      0
         LM,0     MOS:SAVE          RESTORE REGISTER BLOCK
         B        TOTAL
*
MOS:MSG0 TEXT     'MOS CORRECTABLE ERRORS'
MOS:MSG1 TEXT     'M O S   C O R R E C T A B L E   E R R O R S'
MOS:MSG2 TEXT     ' BANK UNIT 0  UNIT 1'
MOS:MSG3 TEXT     '   X  XXXXXX  XXXXXX'
MOS:MSG4 TEXT     '*** MOS COMMAND ERROR'
MOS:MSG5 TEXT     '*** NO ERRORS RECORDED'
MOS:MSG6 TEXT     'UNIT X'
MOS:MSG7 TEXT     'BANK X  <-----*-----*-----*-----*-----*-----'
         TEXT     '*-----*----->'
MOS:MSG8 TEXT     'SLOT       A     B     C     D     F     G  '
         TEXT     '   H     J   '
MOS:MSG9 TEXT     'CHIP-XX  XXXXX XXXXX XXXXX XXXXX XXXXX XXXXX'
         TEXT     ' XXXXX XXXXX '
MOS:UNIT DATA     0                 UNIT INDEX
MOS:BANK DATA     0                 BANK INDEX
MOS:VALS TEXT     ' A10'
UNIT:TXT TEXT     ' 10 '
BANK:TXT TEXT     ' DCBA'
COL:TXT  DATA     'ABCD','EGHJ','KL  '
UNIT:TAB DATA     0,5120,0
BANK:TAB DATA     0,3840,2560,1280,0
MOS:SAVE RES      16
         PAGE
*
*        NAME:    BANK:SUM
*
*        INPUT:   REG 1 - BANK INDEX(1, 2, 3 OR 4)
*                 REG 2 - UNIT NUMBER(1 OR 2)
*
*        OUTPUT:  REG 9 - NUMBER OF ERRORS RECORDED THIS UNIT/BANK
*
*        CALLING SEQUENCE: BAL,7   BANK:SUM
*
*        RETURN:  B   0,7  IF ERRORS FOUND
*                 B   1,7  IF NO ERRORS FOUND
*
BANK:SUM EQU      %
         LW,5     UNIT:TAB,2        UNIT BIAS
         AW,5     BANK:TAB,1        BANK BIAS ADDED
         LI,3     1280              CHIPS/BANK
         LI,9     0                 COUNTER INITIALIZED
         LH,8     CHIPERRS,5        PICK UP CHIP ERROR COUNT
         AW,9     8                 ADD TO TOTAL
         AI,5     1                 NEXT CHIP
         BDR,3    %-3
         LW,9     9                 ANY ERRORS THIS BANK
         BEZ      1,7               B - IF NOT
         B        0,7               ERRORS FOUND
         PAGE
         DEF      MOS:0
         REF      F:F
*
*        NAME:    MOS:0
*
*        PURPOSE: ROUTINE TO PRODUCE THE DETAILED REPORT OF
*                 ALL MOS CORRECTABLE ERRORS RECORDED IN ERRFILE.
*
MOS:0    EQU      %
         BAL,15   F:F               GET CHARACTER
         B        MOS:ERR           COMMAND ERROR
         LI,4     3                 NO. OF POSSIBLE VALUES
         CB,14    MOS:VALS,4        IS THERE A MATCH
         BE       MOS:HIT-1,4       YES
         BDR,4    %-2               LOOP
MOS:ERR  EQU      %
         LI,14    21
         BAL,15   L:PRINT           OUTPUT ERROR MESSAGE
         DATA     MOS:MSG4
         B        R:COM             RETURN TO ROOT
MOS:HIT  B        MOS:ALL           CHECK FOR 'ALL'
         B        %+1               UNIT FOUND
         AI,4     -1                DECREMENT TO UNIT INDEX
         STW,4    MOS:UNIT          SAVE UNIT INDEX
         BAL,15   F:F               GET CHARACTER
         B        MOS:ERR           COMMAND ERROR
         CI,14    '/'               SEPARATOR SHOULD BE '/'
         BNE      MOS:ERR           COMMAND ERROR
         BAL,15   F:F               GET CHARACTER
         B        MOS:ERR           COMMAND
         LI,4     4                 LOAD NO. OF BANKS/UNIT
         CB,14    BANK:TXT,4        CHECK FOR VALID BANK
         BE       MOS:FIND          GOT ONE
         BDR,4    %-2               LOOP
         B        MOS:ERR           COMMAND ERROR
MOS:FIND STW,4    MOS:BANK          SAVEE BANK INDEX
         LI,4     MOS:2             ADDRESS OF 'MOS,U/B' ROUTINE
         B        MOS:LCHK          GO CHECK FOR COMMAND TERMINATOR
MOS:ALL  EQU      %
         LI,4     4
         STW,4    MOS:BANK          SET INDEX FOR BANK A
         LI,4     2                 TWO L'S SHOULD BE IN BUFFER
         STW,4    MOS:UNIT          SET INDEX FOR UNIT 0
         BAL,15   F:F               GET CHARACTER
         B        MOS:ERR           COMMAND ERROR
         CI,14    'L'
         BNE      MOS:ERR           COMMAND ERROR
         BDR,4    %-4               GET 2ND L
         LI,4     MOS:1             ADDRESS OF 'MOS,ALL'ROUTINE
MOS:LCHK BAL,15   F:F               IS THERE ANOTHER CHARACTER
         B        %+2               IS NOT - LET'S GO
         B        MOS:ERR           COMMAND ERROR
         LCI      0
         STM,0    MOS:SAVE          SAVE REGISTER BLOCK
         BAL,15   L:SPACE2          SKIP 2
         LI,14    43
         BAL,15   L:PRINT           OUTPUT HEADING
         DATA     MOS:MSG1
         BAL,15   L:PRINT           UNDERLINE
         DATA     SUMDOT
         BAL,15   L:SPACE           SKIP 1
         BAL,15   DSP:              FROM-TO TIME/DATE
         BAL,15   L:SPACE2          SKIP 2
         MTW,1    REW:FLAG          MUST OPEN ERRILE FIRST
         LI,4     5120              SIZE OF CHIPERRS TABLE
         STW,0    CHIPERRS-1,4      ZERO CHIPERRS TABLE
         BDR,4    %-1
MOS:READ BAL,15   READ:ERF          READ ERRFILE
         CI,15    0                 AT EOF
         BE       *MOS:SAVE+4       YES - GO TO MOS:1 OR MOS:2
         LB,4     BUFFER            GET ERROR TYPE
         CI,4     X'43'             MEMORY ERROR
         BNE      MOS:READ          NEXT
         BAL,15   MOS:RCRD          CHK FOR MOS CORRECTABLE ERROR
         B        MOS:READ          NEXT RECORD
         PAGE
*
*
*
*        PURPOSE: ROUTINE OUTPUTS THE HEADERS FOR THE
*                 MOS CORRECTABLE ERROR REPORT FOR THE UNIT AND
*                 BANK WHOSE INDICES ARE RESPECTIVELY CONTAINED
*                 IN MOS:UNIT AND MOS:BANK
*
*        CALLING SEQUENCE:  BAL,4    MOS:HDRS
*
MOS:HDRS EQU      %
         BAL,15   L:SPACE           SKIP 1
         LW,5     MOS:UNIT          GET UNIT INDEX
         LB,5     UNIT:TXT,5        LOAD UNIT TEXT
         LI,7     BA(MOS:MSG6)+5    UNIT POSITION IN MSG
         STB,5    0,7               STORE IN MESSAGE
         LW,5     MOS:BANK          GET BANK INDEX
         LB,5     BANK:TXT,5        LOAD BANK TEXT
         LI,7     BA(MOS:MSG7)+5    BANK POSITION
         STB,5    0,7               STORE IN MESSAGE
         LI,14    6
         BAL,15   L:PRINT           OUTPUT UNIT HDR
         DATA     MOS:MSG6
         LI,14    57
         BAL,15   L:PRINT           OUTPUT BANK HDR
         DATA     MOS:MSG7
         LI,14    57
         BAL,15   L:PRINT           OUTPUT SLOT HDR
         DATA     MOS:MSG8
         OR,13    L(X'80000000')    INDICATE HDRS ARE OUT
         B        0,4               RETURN
         PAGE
*
*        NAME:    MOS:TOT
*
*        PURPOSE: TO DETERMINE FOR THE UNIT AND BANK WHOSE INDICES
*                 ARE RESPECTIVELY CONTAINED IN MOS:UNIT AND MOS:BANK
*                 THE NUMBER OF ERRORS WHICH HAVE BEEN REPORTED FOR
*                 EACH CHIP.  A REPORT IS PRODUCED SHOWING FOR EACH
*                 CHIP THE NUMBER OF ERRORS WHICH HAVE OCCURRED PER
*                 SLOT.
*
*        CALLING SEQUENCE: BAL,15   MOS:TOT
*
*        OUTPUT:  R13 - BIT0  SET IF ERROR FOUND FOR UNIT/BANK
*                       BIT1  SET WHEN ERROR FOUND FOR A GIVEN CHIP
*                             IN ANY SLOT.
*
MOS:TOT  EQU      %
         STW,15   MOS:SAVE+15       SAVE RETURN
         LI,13    0                 RESET ERROR INDICATOR
         LW,1     L(C'CHIP')
         STW,1    MOS:MSG9          INITIALIZE CHIP MESSAGE
         LW,1     MOS:UNIT          GET UNIT INDEX
         LW,2     UNIT:TAB,1        INDEX TO UNIT IN CHIPERRS TABLE
         LW,1     MOS:BANK          GET BANK INDEX
         AW,2     BANK:TAB,1        INDEX TO BANK IN CHIPERRS TABLE
         LI,12    0                 CHIP COUNTER INITIALIZED
MOS:SLT0 LI,10    8                 8 SLOTS/BANK
         LI,4     BA(MOS:MSG9)+8    POSITION OF ERROR COUNT IN MSG
MOS:SLT1 LH,9     CHIPERRS,2        GET ERRORS THIS CHIP
         BEZ      %+2               NO ERRORS RECORDED
         OR,13    L(X'40000000')    INDICATE ERROR THIS LINE
         AI,4     1                 POSITION TO CHIP ERROR PLACEMENT
         LI,5     5                 5 DIGIT ERROR COUNT
         BAL,7    BIN:DEC           CONVERT TO DECIMAL AND STORE
         AI,2     160                NEXT SLOT FOR THIS CHIP
         BDR,10   MOS:SLT1          B - IF NOT LAST SLOT
         LC       13                CHECK FLAGS
         BCR,4    MOS:PASS          B - IF NO ERRORS THIS LINE
         BCS,8    %+2               B - IF HEADINGS ALREADY OUT
         BAL,4    MOS:HDRS          OUTPUT HEADERS
         LW,9     12                LOAD CURRENT CHIP NUMBER
         LI,7     7
         LI,8     ' '               A BLANK TO
         STB,8    WA(MOS:MSG9),7       CLEAR CHIP COLUMN LETTER
         MTW,0    MOS:128
         BEZ      MOS:NT
         LI,8     0
         DW,8     =20               20 CHIPS/DOUBLE ROW
         LI,5     7                 WE MUST INVERT ROW NUMBER
         SW,5     9                 FOR M128'S
         SCS,8    31                LOW ORDER BIT DECIDES WHETHER
         MTW,0    8
         BLZ      %+3
         AND,8    =15
         AI,5     11
         LW,9     5
         LW,5     8
         LB,5     COL:TXT,5         GET COLUMN CODE
         STB,5    WA(MOS:MSG9),7    WRITE IT OUT
MOS:NT   EQU   %
         LI,5     2                 TWO BYTE MAX
         LI,4     BA(MOS:MSG9)+5    POSITION TO CHIP NO. IN MSG
         BAL,7    BIN:DEC           CONVERT TO DECIMAL AND STORE
         LI,14    57
         BAL,15   L:PRINT           OUTPUT CHIP ERROR LINE
         DATA     MOS:MSG9
         LW,14    L(C'    ')
         STW,14   MOS:MSG9          CLEAR 'CHIP' FROM FURTHER MSGS
         AND,13   L(X'80000000')    RESET ERROR LINE INDICATOR
MOS:PASS AI,2     1-160*8           SET INDEX TO NEXT CHIP NO
         AI,12    1                 INCREMENT CHIP NUMBER
         CI,12    160               160 CHIPS/SLOT
         BE       *MOS:SAVE+15      RETURN - IF ALL CHIPS PROCESSED
         B        MOS:SLT0          CHECK NEXT CHIP
         PAGE
*
*  'MOS,ALL' ROUTINE
*
MOS:1    EQU      %
         LI,8     0                 RESET REPORT ERROR INDICATOR
MOS:11   BAL,15   MOS:TOT
         LC       13                PICK UP FLAGS
         BCR,8    %+2               B - NO ERROR FOUND THIS UNIT/BANK
         MTW,1    8                 INDICATE ERROR FOUND
         MTW,-1   MOS:BANK          DECREMENT BANK INDEX
         BNEZ     MOS:11            PROCESS NEXT BANK
         MTW,4    MOS:BANK          RESET BANK INDEX
         MTW,-1   MOS:UNIT          DECREMENT UNIT INDEX
         BNEZ     MOS:11            PROCESS NEXT UNIT
         MTW,0    8                 ANY ERROR FOUND
         BNEZ     MOS:EXIT          YES - EXIT
MOS:NONE LI,14    22
         BAL,15   L:PRINT           OUTPUT NO ERRORS MESSAGE
         DATA     MOS:MSG5
MOS:EXIT BAL,15   L:SPACE2          SKIP 2
         LCI      0
         LM,0     MOS:SAVE          RESTORE REGISTER BLOCK
         B        R:COM             RETURN TO ROOT
         PAGE
*
*  'MOS,UNIT/BANK' ROUTINE
*
MOS:2    BAL,15   MOS:TOT
         LC       13                PICK UP FLAGS
         BCR,8    MOS:NONE          NO ERRORS FOUND THIS UNIT/BANK
         B        MOS:EXIT          EXIT
TOTAL    EQU      %                                                     ELS30656
         BAL,15   L:SPACE3                                              S3--0044
*                                                                       ELS30660
         LW,14    SUMXY             LOAD TOTAL VALUE                    ELS30661
         AW,14    SUMX              SUMX+SUMXY                          ELS30662
         BEZ      NONE         NO ERRORS.............                   ELS30663
         LI,13    3                                                     ELS30664
         BAL,15   HEXFIVE                                               ELS30665
         DATA     TOTLER+3                                              ELS30666
         LI,14    32                                                    ELS30667
         BAL,15   L:PRINT                                               ELS30668
         DATA     TOTLER            PRINT TOTAL ERRORS                  ELS30669
         B        %+4          SKIP ..........                          ELS30670
NONE     LI,14    9                                                     ELS30671
         BAL,15   L:PRINT                                               ELS30672
         DATA     NONETX                                                ELS30673
         BAL,15   L:SPACE3                                              S3--0046
         B        R:COM             READ ANOTHER COMMAND                ELS30677
NONETX   TEXT     'NO ERRORS'                                           ELS30678
         PAGE                                                           ELS30679
*                                                                       ELS30680
*                                                                       ELS30681
* THIS SUBROUTINE WILL SUPRESS LEADING ZEROES BEFORE OUPUT              ELS30682
* OF THE BUFFER....  ALL X'F0' BEFORE A VALID EBCIDC NUMBER             ELS30683
* IS SUPRESSED BEFORE OUPUT.                                            ELS30684
* REGISTER 13 IS ASSUMED TO HAVE THE STARTING BYTE                      ELS30685
* REGISTER 12 IS TO HAVE THE AMOUNT OF DECIMALS.                        ELS30686
* REGISTER 14 IS TO HAVE THE ADDRESS OF THE BUFFER....                  ELS30687
*                                                                       ELS30688
*        BAL,15   SUPZR    ...........CALL........                      ELS30689
*                                                                       ELS30690
*  ALL REGISTERS ARE SAVED................                              ELS30691
*                                                                       ELS30692
*                                                                       ELS30693
SUPZR    LCI      4                 SAVE REGISTERS 13-15 6,7            ELS30694
         STM,12   SUPSAV            2-0 3-1,4-2 5-3                     ELS30695
         LCI      2                                                     ELS30696
         STM,6    SUPSAV+4                                              ELS30697
         LW,6     SUPSAV            FETCH COMPLEMENT (2)                ELS30698
         AI,6     -1                ADD 1........(-#) + 1               ELS30699
         LW,7     13           SET REGISTER 7 WITH STARTING BYTE CNT    ELS30700
DT0      LB,15    *14,7        FETCH THE FISTR LEADING NUMBER.          ELS30701
         CI,15    X'F0'        AN EBCIDC ZERO                           ELS30702
         BNE      DT1          B: IF NOT EQUAL.....                     ELS30703
         LI,15    X'40'        SUBSTITUTE WITH BLANKS.                  ELS30704
         STB,15   *14,7             STORE TO OUPUT BUFF.                ELS30705
         AI,7     1            BUMP 7                                   ELS30706
         BDR,6    DT0               LOOP TILL DONE.......               ELS30707
DT1      LCI      4                                                     ELS30708
         LM,12    SUPSAV            RESTORE REGISTERS.                  ELS30709
         LW,6     SUPSAV+4                                              ELS30710
         LW,7     SUPSAV+5                                              ELS30711
         B        *15                                                   ELS30712
SUPSAV   RES      6                                                     ELS30713
*                                                                       ELS30714
*                                                                       ELS30715
*                                                                       ELS30716
*                                                                       ELS30717
         PAGE                                                           ELS30718
*                                                                       ELS30719
*                                                                       ELS30720
* THIS SUBROUTINE CALCULATE EACH I/O COUNT.                             ELS30721
*                                                                       ELS30722
*                                                                       ELS30723
IOCNTFX  EQU      %                                                     ELS30724
         STW,4    SAVCNT                                                ELS30725
         LCI      5                                                     ELS30726
         STM,11   SAVCNT+1                                              ELS30727
         STW,0    BADFLG                                                ELS30728
         LW,14    IOTBL                                                 ELS30729
         CI,14    0                 NO ENTRY OF IOADR CK                ELS30730
         BE       TOTAL             SKIP DEV. ERR. PRINT                ELS30731
         AI,14    1                                                     ELS30732
         STW,14   ENTRYCNT                                              ELS30733
         LI,4     1                 X4=1                                ELS30734
LFXCNT   EQU      %                                                     ELS30735
         CW,4     ENTRYCNT                                              ELS30736
         BE       ENDX              FINISH FXIOCNT                      ELS30737
         LW,11    ADDRTBL,4                                             ELS30738
         STW,11   WORK                                                  ELS30739
*                                                                       ELS30740
         LW,13    WORK                                                  ELS30741
         AI,13    4                 ACCESS SUBTOTL                      ELS30742
         LW,14    *13                                                   ELS30743
         CW,14    0                 DEV. ERR. ENTRY=0 CK                ELS30744
         BE       SKIPCAL           SKIP IOCNT CALCULATIONS             ELS30745
         BIFSYS   *(CPV,BADF)       B IF NOT CPV                        ELS30746
*                                                                       ELS30747
GOODX    EQU      %                                                     ELS30748
         BAL,15   CKIOCNT                                               ELS30749
         LW,13    BADFLG                                                ELS30750
         CW,13    0                                                     ELS30751
         BE       CALCNT            CALCULATE IOCNT                     ELS30752
         LW,11    STARS                                                 ELS30753
         LW,13    WORK                                                  ELS30754
         AI,13    11                ACCESS IOCNT ENTRY                  ELS30755
         STW,11   *13               STORE STARS TO IOCNT ENTRY          ELS30756
*                                                                       ELS30757
*                                                                       ELS30758
         STW,0    BADFLG            RESET BADFLG                        ELS30759
SKIPCAL  EQU      %                                                     ELS30760
         AI,4     1                                                     ELS30761
         B        LFXCNT            FX NEXT ARRAY                       ELS30762
*                                                                       ELS30763
CALCNT   EQU      %                                                     ELS30764
         LW,13    WORK                                                  ELS30765
         AI,13    10                DELTA ENTRY                         ELS30766
         LW,12    *13               R12=DELTA                           ELS30767
*                                                                       ELS30768
         LW,13    WORK                                                  ELS30769
         AI,13    9                 CT                                  ELS30770
         LW,11    *13               R11=CT                              ELS30771
         AW,11    12                DELTA+CT=IOCNT=R11                  ELS30772
         LW,13    WORK                                                  ELS30773
         AI,13    11                IOCNT ENTRY                         ELS30774
         STW,11   *13               STORE IOCNT                         ELS30775
         B        SKIPCAL                                               ELS30776
BADF     STW,1    BADFLG                                                ELS30777
         B        GOODX+1           SKIP CKIOCNT ROUTINE                ELS30778
*                                                                       ELS30779
ENDX     EQU      %                                                     ELS30780
         LW,4     SAVCNT                                                ELS30781
         LCI      4                                                     ELS30782
         LM,11    SAVCNT+1                                              ELS30783
         B        *SAVCNT+5                                             ELS30784
*                                                                       ELS30785
*                                                                       ELS30786
*                                                                       ELS30787
*                                                                       ELS30788
* THIS SUBROUTINE CHECK I/O COUNT CRITERIA.  IF IT IS NOT               ELS30789
* MET THE BADFLG IS SET.                                                ELS30790
*                                                                       ELS30791
*                                                                       ELS30792
CKIOCNT  EQU      %                                                     ELS30793
         STW,4    SAVCAL+7                                              ELS30794
         LCI      7                                                     ELS30795
         STM,9    SAVCAL                                                ELS30796
*                                                                       ELS30797
         LW,13    TIME:1                                                ELS30798
         LW,14    TIME:2                                                ELS30799
         LW,9     TIMEFLG                                               ELS30800
         BEZ      CALCK                                                 ELS30801
         LW,14    YEAR:1                                                ELS30802
         LW,13    YEAR:2                                                ELS30803
         CW,14    13                                                    ELS30804
         BNE      CKYEAR            CK YEAR BOUNDARY                    ELS30805
         LW,13    DATE:1                                                ELS30806
         LW,14    DATE:2                                                ELS30807
         CW,13    14                                                    ELS30808
         BE       CALCK                                                 ELS30809
         AI,13    1                 D1+1                                ELS30810
         CW,13    14                                                    ELS30811
         BNE      EXT                                                   ELS30812
TIMETST  EQU      %                                                     ELS30813
         LW,13    TIME:1            T1                                  ELS30814
         LW,14    TIME:2            T2                                  ELS30815
         CW,14    13                                                    ELS30816
         BL       CALCK                                                 ELS30817
         B        EXT                                                   ELS30818
CKYEAR   EQU      %                                                     ELS30819
         AI,14    1                 YEAR+1                              ELS30820
         CW,14    13                                                    ELS30821
         BNE      EXT                                                   ELS30822
         LW,13    DATE:1                                                ELS30823
         LW,14    DATE:2                                                ELS30824
         AI,14    365               D2+365                              ELS30825
         AI,13    1                 D1+1                                ELS30826
         CW,14    13                                                    ELS30827
         BE       TIMETST                                               ELS30828
         B        EXT                                                   ELS30829
CALCK    EQU      %                                                     ELS30830
         LW,11    WORK                                                  ELS30831
         AI,11    5                                                     ELS30832
         LW,10    *11               R10=TB                              ELS30833
         LW,11    WORK                                                  ELS30834
         AI,11    7                                                     ELS30835
         LW,9     *11               R9=TC                               ELS30836
         SW,10    13                TB-T1=TX                            ELS30837
         STW,14   12                R12=T2                              ELS30838
         SW,14    9                 T2-TC=TY                            ELS30839
         SW,12    13                T2-T1=R12=TZ                        ELS30840
         AW,10    14                TX+TY=TW                            ELS30841
         LI,4     4                                                     ELS30842
         STW,10   11                CHANGE TO ODD REG.                  ELS30843
         MW,11    4                 TWX4                                ELS30844
         CW,12    11                TZ G.E. 4TW CK                      ELS30845
         BGE      EXT                                                   ELS30846
         STW,1    BADFLG            CRITERIA NOT MET                    ELS30847
         B        EXT                                                   ELS30848
*                                                                       ELS30849
EXT      EQU      %                                                     ELS30850
         LCI      6                                                     ELS30851
         LM,9     SAVCAL                                                ELS30852
         LW,4     SAVCAL+7                                              ELS30853
         B        *SAVCAL+6                                             ELS30854
*                                                                       ELS30855
*                                                                       ELS30856
SAVCAL   RES      8                                                     ELS30857
*                                                                       ELS30858
*                                                                       ELS30859
*                                                                       ELS30860
*                                                                       ELS30861
* THIS SUBROUTINE SORTS IOTBL IN ASCENDING ORDER.                       ELS30862
*                                                                       ELS30863
*                                                                       ELS30864
FXINDX4  EQU      %                                                     ELS30865
         LCI      6                                                     ELS30866
         STM,4    SAVX4+1                                               ELS30867
         STW,15   SAVX4                                                 ELS30868
         LW,6     IOTBL                                                 ELS30869
         STW,6    COUNT                                                 ELS30870
         LI,4     1                                                     ELS30871
LPXX     CW,4     ENTRYCNT                                              ELS30872
         BE       SORTIO                                                ELS30873
         LW,5     IOTBL,4                                               ELS30874
         STB,4    5                                                     ELS30875
         STW,5    IOTBLX,4                                              ELS30876
         AI,4     1                                                     ELS30877
         B        LPXX                                                  ELS30878
SORTIO   EQU      %                                                     ELS30879
*                                                                       ELS30880
         LI,4     0                                                     ELS30881
         LI,5     0                                                     ELS30882
LOOP1    LW,6     IOTBLX+1,4                                            ELS30883
         STW,6    TEMPO             SAVE 6                              ELS30884
         AND,6    XXXXFFFF          MASK FIRST HALF WORD                ELS30885
LOOP2    LW,8     IOTBLX+1,5        FETCH NEXT WORD                     ELS30886
         AND,8    XXXXFFFF                                              ELS30887
         CW,6     8                                                     ELS30888
         BL       GOX                                                   ELS30889
         LW,6     TEMPO                                                 ELS30890
         XW,6     IOTBLX+1,5                                            ELS30891
         STW,6    TEMPO                                                 ELS30892
         AND,6    XXXXFFFF                                              ELS30893
GOX      AI,5     1                                                     ELS30894
         CW,5     COUNT                                                 ELS30895
         BL       LOOP2                                                 ELS30896
         LW,6     TEMPO                                                 ELS30897
         STW,6    IOTBLX+1,4                                            ELS30898
         AI,4     1                                                     ELS30899
         LW,5     4                                                     ELS30900
         CW,4     COUNT                                                 ELS30901
         BL       LOOP1                                                 ELS30902
         LCI      6                                                     ELS30903
         LM,4     SAVX4+1                                               ELS30904
         B        *SAVX4                                                ELS30905
*                                                                       ELS30906
*                                                                       ELS30907
SAVX4    RES      8                                                     ELS30908
TEMPO    DATA     0                                                     ELS30909
COUNT    DATA     0                                                     ELS30910
         PAGE                                                           ELS30911
*                                                                       ELS30912
*                                                                       ELS30913
*                                                                       ELS30914
*                                                                       ELS30915
SUMTITLE TEXT     'E R R O R  S U M M A R Y'                            ELS30916
SUMDOT   TEXT     '- - - - - - - - - - - - - - - - - - - - - -'
SYSERR   TEXT     'SYSTEM ERRORS'                                       ELS30918
TYPEERR  TEXT     'TYPE                  ERRORS'                        ELS30919
CODETBL  DATA     X'11121315',X'17181921',X'22232730',X'31324142'       ELS30920
         DATA     X'43441D16'                                           ELS30921
CDETBL   DATA     X'101A1B1E',X'1F202428',X'34353637'                   ELS30922
         DATA     X'38395051',X'5253262D',X'2E2F0000'                   S3--0048
         DATA     0                                                     ELS30924
*                                                                       ELS30925
CNTBL    EQU      %                                                     ELS30926
         RES      16                                                    ELS30927
CNTX     DATA     0                                                     ELS30928
         RES      22              FOR CP-V ERROR CODE COUNTS            S3--0050
CNTXX    DATA     0               (UNKNOWN ENTRIES TOTAL)               S3--0052
         DATA     0,0             -------WHO KNOWS-------               S3--0053
*                                                                       S3--0054
*                                                                       S3--0055
TTL      EQU      (CNTXX+2-CNTBL)+1  TTL TBL SIZE                       S3--0056
TTLCPR   EQU      (CNTX-CNTBL)    # OF CPR CODES                        S3--0057
TTLCPVO  EQU      (CNTXX-(CNTX+1))   ONLY CP-V ERROR CODES              S3--0058
*                                                                       ELS30931
*                                                                       ELS30932
*                                                                       ELS30933
SYSTLE   EQU      %                                                     ELS30934
         TEXT     'PARITY ERROR (17)           '                        S3--0060
         TEXT     'SYSTEM STARTUP (18)         '                        S3--0061
         TEXT     'WATCHDOG TIMER (19)         '                        S3--0062
         TEXT     'CONFIGURATION (21)          '                        S3--0063
         TEXT     'SYSTEM I.D. (22)            '                        S3--0064
         TEXT     'TIME STAMP (23)             '                        S3--0065
         TEXT     'OPERATOR MESSAGE (27)       '                        S3--0066
         TEXT     'PROCESSOR FAULT INT (30)    '                        S3--0067
         TEXT     'MEMORY FAULT INT (31)       '                        S3--0068
         TEXT     'SEC. POLL RECORD (32)       '                        S3--0069
         TEXT     'PROCESSOR CONFIG. (41)      '                        S3--0070
         TEXT     'MEMORY PARITY SEC (42)      '                        S3--0071
         TEXT     'MEMORY PARITY SEC (43)      '                        S3--0072
         TEXT     'MEMORY PARITY SEC (44)      '                        S3--0073
         TEXT     'INSTRUCTION EXCEP. (1D)     '                        S3--0074
         TEXT     'DEVICE ERROR SEC (16)       '                        S3--0075
         TEXT     'UNKNOWN TYPE (CP-R,RBM)     '                        S3--0076
         TEXT     'COPY ERROR (10)             '                        S3--0077
         TEXT     'FILE INCONSISTENCY (1A)     '                        S3--0078
         TEXT     'SYMBIONT INCONSIS. (1B)     '                        S3--0079
         TEXT     'LOST ENTRIES (1E)           '                        S3--0080
         TEXT     'DUPLICATE ENTRIES (1F)      '                        S3--0081
         TEXT     'POWER FAILSAFE (20)         '                        S3--0082
         TEXT     'BAD GRAN. RELEASE (24)      '                        S3--0083
         TEXT     'I/O ACTIVITY COUNT (28)     '                        S3--0084
         TEXT     'INSTRUCT. FAIL(AIO) (34)    '                        S3--0085
         TEXT     'INSTRUCT. FAIL(RIO) (35)    '                        S3--0086
         TEXT     'INSTRUCT. FAIL(SIO) (36)    '                        S3--0087
         TEXT     'INSTRUCT. FAIL(TIO) (37)    '                        S3--0088
         TEXT     'INSTRUCT. FAIL(TDV) (38)    '                        S3--0089
         TEXT     'INSTRUCT. FAIL(HIO) (39)    '                        S3--0090
         TEXT     'ENQUEUE TBL OVERFLOW(50)    '                        S3--0091
         TEXT     'PARTITIONED RESOURCE(51)    '                        S3--0092
         TEXT     'RETURNED RESOURCE (52)      '                        S3--0093
         TEXT     'PRIVATE PACK INCONS.(53)    '                        S3--0094
         TEXT     'REMOTE PROCESSING (26)      '                        S3--0095
         TEXT     'PARITY ERROR (2D)           '                        S3--0096
         TEXT     'WATCHDOG TIMER (2E)         '                        S3--0097
         TEXT     'INSTRUCTION EXCEP. (2F)     '                        S3--0098
         TEXT     'UNKNOWN TYPE (CP-V)         '                        S3--0099
*                                                                       S3--0100
*                                                                       S3--0101
SYSTLA   DATA     SYSTLE                                                ELS30975
HEX2ADDR DATA     DATAHEX2                                              ELS30976
SUMX     DATA     0                                                     ELS30977
*                                                                       ELS30978
DEVERR   TEXT     'DEVICE ERRORS'                                       ELS30979
DEVT:1   TEXT     '      IO     SIO   UNEXP   DEV    DEV      IO'       ELS30980
DEVT:2   TEXT     'MDL   ADRS   FAIL  INTRPT  ERROR  TIMEOUT  ACTIVITY' ELS30981
TOTLER   TEXT     'TOTAL ERRORS:                    '                   ELS30982
X40X     DATA     X'40404040'                                           ELS30983
WORK     DATA     0                                                     ELS30984
OUTBUFF  RES      44                                                    ELS30985
X6DX     DATA     X'40406D6D'                                           ELS30986
ENTRYCNT DATA     0                                                     ELS30987
ETYPE    DATA     0                                                     ELS30988
XXXXFFFF DATA     X'0000FFFF'                                           ELS30989
CNT1     DATA     0                                                     ELS30990
CNT2     DATA     0                                                     ELS30991
IDX12    DATA     0                                                     ELS30992
IDX13    DATA     0                                                     ELS30993
XFFFFX   DATA     X'0000FFFF'                                           ELS30994
*                                                                       S3--0103
*                 TABLES.........                                       S3--0104
*        ENTRY IN DATA TABLE (DATATBL)....                              S3--0105
*        0        COUNT--#11 ERRORS                                     S3--0106
*        1        COUNT--#13 ERRORS                                     S3--0107
*        2        COUNT--#15 ERRORS                                     S3--0108
*        3        COUNT--#12 ERRORS                                     S3--0109
*        4        TOTAL COUNTS (11,15,13)                               S3--0110
*        5        TIME OF FIRST ERROR                                   S3--0111
*        6        COUNT (I/O) FOR FIRST DEV ERROR                       S3--0112
*        7        TIME --CURRENT                                        S3--0113
*        8        COUNT TOTAL..                                         S3--0114
*        9                                                              S3--0115
*        10                                                             S3--0116
*        11       I/O COUNT FOR DEVICE                                  S3--0117
*                                                                       S3--0118
*                                                                       S3--0119
DATATBLA DATA     DATATBL         ADDR. OF NEXT AVAILABLE ENTRY         S3--0120
*                                 IN DATATBL                            S3--0121
DATATBL  RES      1200                                                  ELS30996
IOTBL    RES      101             DEV I/O ADR'S (WD1=#ENTRIES NOW)      S3--0123
MODTBL   RES      101                                                   ELS30998
ADDRTBL  RES      101             ADR PTR INTO DATATBL FOR A GIVEN DEV  S3--0125
IOTBLX   RES      101                                                   ELS31000
*                                                                       S3--0127
*                                                                       S3--0128
PATCH    DATA     0                                                     ELS31001
DEVNEW   DATA     0                                                     ELS31002
MODNEW   DATA     0                                                     ELS31003
MODNUM   DATA     0                                                     ELS31004
DEVNUM   DATA     0                                                     ELS31005
ERRMESS1 TEXT     'IOTBL ENTRIES(I/O ADDRESSES) EXCEED 100.'            ELS31006
XCNT     DATA     0                                                     ELS31007
SUMXY    DATA     0                                                     ELS31008
F11      DATA     0                                                     ELS31009
F12      DATA     0                                                     ELS31010
F13      DATA     0                                                     ELS31011
F15      DATA     0                                                     ELS31012
SUM11    DATA     0                                                     ELS31013
SUM12    DATA     0                                                     ELS31014
SUM13    DATA     0                                                     ELS31015
SUM15    DATA     0                                                     ELS31016
TCNT     DATA     0                                                     ELS31017
FST28    DATA     0                                                     ELS31018
SAVE28   RES      20                                                    ELS31019
T28FST   DATA     0                                                     ELS31020
SAVE28X  RES      20                                                    ELS31021
TCNT28   DATA     0                                                     ELS31022
TIMEFLG  DATA     0                                                     ELS31023
SYRSTFLG DATA     0                                                     ELS31024
IOCNTX   DATA     0                                                     ELS31025
WDCNTX   DATA     0                                                     ELS31026
INDXIO   DATA     0                                                     ELS31027
INDXCNT  DATA     0                                                     ELS31028
SAVCNT   RES      6                                                     ELS31029
BADFLG   DATA     0                                                     ELS31030
STARS    TEXT     '   **********   '                                    ELS31031
F28      DATA     0                                                     ELS31032
STARF    DATA     0                                                     ELS31033
SEQFLG   DATA     0                                                     ELS31034
         PAGE                                                           ELS31035
         END      SUM:0                                                 ELS31036
