/ 
/ 
/                   FIRST PRINTING, FEBRUARY 1974
/ 
/ THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO 
/ CHANGE WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED
/ AS A COMMITMENT BY DIGITAL EQUIPMENT CORPORATION.
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPON-
/ SIBILITY FOR ANY ERRORS THAT MAY APPEAR IN THIS
/ DOCUMENT.
/ 
/ THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FUR-
/ NISHED TO THE PURCHASER UNDER A LICENSE FOR USE ON
/ A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH
/ INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR 
/ USE IN SUCH SYSTEM, EXCEPT AS MAY OTHERWISE BE PRO-
/ VIDED IN WRITING BY DIGITAL.
/ 
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/ FOR THE USE OR RELIABILITY OF ITS SOFTWARE ON EQUIP-
/ MENT THAT IS NOT SUPPLIED BY DIGITAL.
/ 
/ COPYRIGHT (C) 1974, BY DIGITAL EQUIPMENT CORPORATION
/ 
/ 
        .EJECT
/	EDIT #6
/
/ COPYRIGHT DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/
/			10/22/71	R. MCLEAN
/			 1/03/73	T. MURRAY
/
/	SCHED -- FORTRAN CALLABLE SUBROUTINE
/		TO SCHEDULE AN RSX TASK.
/
/	CALLING SEQUENCE:
/	    CALL SCHED (TASK NAME, TIME, PRIORITY, EV)
/
/	    TASK NAME=1-5 CHARACTERS
/	    TIME=NAME OF A 5 ELEMENT INTERNAL ARRAY
/		ELEMENT 1=SCHEDULE TIME HOURS
/		ELEMENT 2=SCHEDULE TIME MINUTES
/		ELEMENT 3=SCHEDULE TIME SECONDS
/		ELEMENT 4=RESCHEDULE INTERVAL
/		ELEMENT 5=INTERVAL UNITS
/	    PRIORITY=TASK PRIORITY
/	    EV=EVENT VARIABLE ADDRESS
	.GLOBL	SCHED,.DAA,.FTSB
X10=10
SCHED	0
	JMS*	.DAA	/PICK UP THE CALLER'S ARGUMENTS
	JMP	ARGEND	/SKIP OVER ADDRESSES
TSKNAM	0
DESWD	0
PRTY	0
EVNTY	0
ARGEND	LAC	EVNTY	/PUT EVENT VARIABLE ADDRESS
	DAC	REQEV	/IN REQUEST -- CLEAR ADDRESS
	DZM	EVNTY	/SINCE IT IS OPTIONAL
	LAC*	PRTY	/SAVE REQUESTED PRIORITY
	DAC	REQPRI
	LAW	-5	/SET UP TO MOVE 5
	DAC	PRTY
	LAC	(REQTIM-1)
	DAC*	(X10)
	LAC*	DESWD	/PICK UP AN ELEMENT
	DAC*	X10	/STORE IT IN THE REQUEST
	ISZ	DESWD	/UPDATE ELEMENT POINTER
	ISZ	PRTY	/FINIHED?
	JMP	.-4	/NO TRY AGAIN
	JMS*	.FTSB
	TSKNAM		/CONVERT TASK NAME TO SIXBT
	REQNAM
	CAL	SCHCPB	/ISSUE SCHEDULE REQUEST
	JMP*	SCHED	/RETURN
SCHCPB	2		/FUNCTION CODE
REQEV	0		/EVENT VAR ADR
REQNAM	0		/TASK NAME 1ST HALF
	0		/TASK NAME 2ND HALF
REQTIM	0		/HRS
	0		/MIN
	0		/SEC
	0		/RE-SCHEDULE INTERVAL
	0		/INTERVAL UNITS
REQPRI	0		/PRIORITY
	.END	SCHED