/ 
/ 
/                   FIRST PRINTING, FEBRUARY 1974
/ 
/ THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO 
/ CHANGE WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED
/ AS A COMMITMENT BY DIGITAL EQUIPMENT CORPORATION.
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPON-
/ SIBILITY FOR ANY ERRORS THAT MAY APPEAR IN THIS
/ DOCUMENT.
/ 
/ THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FUR-
/ NISHED TO THE PURCHASER UNDER A LICENSE FOR USE ON
/ A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH
/ INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR 
/ USE IN SUCH SYSTEM, EXCEPT AS MAY OTHERWISE BE PRO-
/ VIDED IN WRITING BY DIGITAL.
/ 
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/ FOR THE USE OR RELIABILITY OF ITS SOFTWARE ON EQUIP-
/ MENT THAT IS NOT SUPPLIED BY DIGITAL.
/ 
/ COPYRIGHT (C) 1974, BY DIGITAL EQUIPMENT CORPORATION
/ 
/ 
        .EJECT
/	EDIT #5
/
/ COPYRIGHT DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/
/			10/22/71	R. MCLEAN
/			 1/03/73	T. MURRAY
/
/	RUN -- FORTRAN CALLABLE SUBROUTINE
/		TO RUN AN RSX TASK.
/
/	CALLING SEQUENCE:
/	    CALL RUN (TN,ITP,IP,EV)
/
/	    IN=TASK NAME 1-5 CHARACTERS
/	    ITP=NAME OF 4 ELEMENT ARRAY
/	     EL1=SCHEDULE DELTA TIME
/	     EL2=INTERVAL UNITS
/	     EL3=RESCHEDULE INTERVAL
/	     EL4=RESCHEDULE INTERVAL UNITS
/	    IP=TASK PRIORITY
/	    IEV=EVENT VARIABLE
/
ECLA=641000
X10=10
	.GLOBL	RUN,.DAA,.FTSB
RUN	0
	JMS*	.DAA	/PICK UP THE CALLER'S ARGUMENTS
	JMP	ARGEND	/SKIP OVER ARGUMENTS
TSKNAM	0
DESWD	0
PRTY	0
EVNTY	0
ARGEND	LAC	EVNTY	/PUT EVENT VARIABLE ADDRESS
	DAC	REQEV	/IN REQUEST -- CLEAR ADDRESS
	DZM	EVNTY	/SINCE IT IS OPTIONAL
	LAC*	PRTY 	/SAVE REQUESTED PRIORITY
	DAC	REQPRI
	LAW	-4	/SET UP TO MOVE 4
	DAC	PRTY
	LAC	(REQTIM-1)
	DAC*	(X10)
	LAC*	DESWD	/PICK UP AN ELEMENT
	DAC*	X10	/STORE IT IN THE REQUEST
	ISZ	DESWD	/UPDATE POINTER
	ISZ	PRTY	/FINISHED?
	JMP	.-4	/NO TRY AGAIN
	JMS*	.FTSB
	TSKNAM		/CONVERT TSKNAM TO SIXBT
	REQNAM
	CAL	RUNCPB	/ISSUE RUN REQUEST
	JMP*	RUN	/RETURN
RUNCPB	3		/FUNCTION
REQEV	0		/EVENT VARIABLE ADDRESS
REQNAM	0		/TASK NAME 1ST HALF
	0		/TASK NAME 2ND HALF
REQTIM	0		/SCHEDULE DELTA TIME
	0		/SCHEDULE UNITS
	0		/RESCHEDULE INTERVAL
	0		/INTERVAL UNITS
REQPRI	0		/PRIORITY
	.END	RUN