/ 
/ 
/                   FIRST PRINTING, FEBRUARY 1974
/ 
/ THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO 
/ CHANGE WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED
/ AS A COMMITMENT BY DIGITAL EQUIPMENT CORPORATION.
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPON-
/ SIBILITY FOR ANY ERRORS THAT MAY APPEAR IN THIS
/ DOCUMENT.
/ 
/ THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FUR-
/ NISHED TO THE PURCHASER UNDER A LICENSE FOR USE ON
/ A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH
/ INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR 
/ USE IN SUCH SYSTEM, EXCEPT AS MAY OTHERWISE BE PRO-
/ VIDED IN WRITING BY DIGITAL.
/ 
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/ FOR THE USE OR RELIABILITY OF ITS SOFTWARE ON EQUIP-
/ MENT THAT IS NOT SUPPLIED BY DIGITAL.
/ 
/ COPYRIGHT (C) 1974, BY DIGITAL EQUIPMENT CORPORATION
/ 
/ 
        .EJECT
/	EDIT # 1
 
/COPYRIGHT 1973, DIGITAL EQUIPMENT CORP., MAYNARD, MASS., U.S.A.
 
/		3 DEC 73	T.A. MURRAY,M.HEBENSTREIT
 
/FORTRAN CALLABLE RSX UTILITY ROUTINE TO EXECUTE QJOB DIRECTIVE
/	CALLING SEQUENCE
/		CALL QJOB (LUN, FILNAM, WORD5, WORD6 (EV))
/	WHERE
/		LUN IS THAT OF THE DEVICE ON WHICH THE BATCH
/		 JOB RESIDES
/		FILNAM IS A TWO WORD VARIABLE (REAL OR D.I.) WHICH
/		 HOLDS THE 5/7 ASCII FORM OF THE FILENAME OF THE 
/		 BATCH JOB
/		WORD 5 AND WORD 6 ARE THE WORDS USED IN THE QJOB CPB
/		 AS WORDS 5 AND 6. THEY ARE INTEGERS.
/		EV IS THE INTEGER EVENT VARIABLE
 
	.GLOBL	QJOB,  .FTSB,  .DAA
 
QJOB	0
	JMS*	.DAA
	JMP	ARGEND
LUN	0
FILNAM	0
WORD5	0
WORD6	0
EV	0
 
ARGEND	LAC	EV	/MOVE EV TO QJOB CPB.  
	DAC	QEV
	DZM	EV	/ZERO IT OUT, IN CASE NOT SPECIFIED ON NEXT CALL
	JMS*	.FTSB	/CONVERT PASSED FILENAME FROM 5/7 ASCII TO 6BIT
	FILNAM		/(PASSED FILENAME)
	QNAM		/DESTINATION FILENAME)
	LAC*	LUN	/PUT LUN INTO LEFT HALF OF CPB WORD 4
	AND	(777)
	SWHA
	DAC	QLUN
	LAC*	WORD5	/GET WORD5 FOR THE CPB
	DAC	QWD5
	LAC*	WORD6	/GET WORD6 FOR THE CPB
	DAC	QWD6
	CAL	QJCPB
	JMP*	QJOB
 
QJCPB	33		/WORD0 OF QJOB CPB
QEV	0		/WORD1, EV ADDRESS
QNAM	0		/WORD2 AND WORD3, 6BIT FILENAME
	0
QLUN	0		/WORD4 -- LUN IN BITS 0-8
QWD5	0		/WORD5 -- JOB INFORMATION
QWD6	0		/WORD6 -- JOB INFORMATION
	0		/WORD7 -- RESERVED FOR FUTURE BATCH PARAMETERS
 
	.END