/ 
/ 
/                   FIRST PRINTING, FEBRUARY 1974
/ 
/ THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO 
/ CHANGE WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED
/ AS A COMMITMENT BY DIGITAL EQUIPMENT CORPORATION.
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPON-
/ SIBILITY FOR ANY ERRORS THAT MAY APPEAR IN THIS
/ DOCUMENT.
/ 
/ THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FUR-
/ NISHED TO THE PURCHASER UNDER A LICENSE FOR USE ON
/ A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH
/ INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR 
/ USE IN SUCH SYSTEM, EXCEPT AS MAY OTHERWISE BE PRO-
/ VIDED IN WRITING BY DIGITAL.
/ 
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/ FOR THE USE OR RELIABILITY OF ITS SOFTWARE ON EQUIP-
/ MENT THAT IS NOT SUPPLIED BY DIGITAL.
/ 
/ COPYRIGHT (C) 1974, BY DIGITAL EQUIPMENT CORPORATION
/ 
/ 
        .EJECT
/	EDIT #4
/
/ COPYRIGHT 1973,  DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/
/			2/24/71		R. MCLEAN
/			14 JUN 73	T. MURRAY
/			28 JAN 74	M. HEBENSTREIT
/
/	DSKDAL -- FORTRAN CALLABLE SUBROUTINE TO DEALLOCATE DISK
/		  STORAGE SPACE
/
/	CALLING SEQUENCE:
/		CALL DSKDAL (ITA,DVCODE,UNIT,IEV)
/		  ITA=CONTROL TABLE ARRAY
/		  EL1=AMOUNT OF SPACE TO BE RETURNED
/		  EL2=DISK PLATTER NUMBER (EXTENSION OF EL3)
/		  EL3=DISK STARTING ADDRESS
/		DVCODE=DISK DEVICE CODE
/			0=SYSTEM DISK  2=RF  3=RB  24=RK
/		UNIT=UNIT NUMBER OF DISK DEVICE
/		IEV=EVENT VARIABLE
/
	.GLOBL	DSKDAL,.DAA
DSKDAL	0
	JMS*	.DAA	/PICK UP CALLER'S ARGUMENTS
	JMP	ARGEND
TBLADR	0
DVCODE	0
UNIT	0
EVNTV	0
ARGEND	LAC	EVNTV	/PICK UP REQUESTED EVENT
	DAC	REQEV	/VARIABLE ADDRESS -- CLEAR
	DZM	EVNTV	/POINTER SINCE IT IS OPTIONAL
	LAC*	DVCODE	/MOVE DEVICE CODE TO 5TH WORD
	DAC	DSKTYP	/OF CPB
	LAC	TBLADR	/DEFINE CTRL TBL ADR IN CPB
	DAC	TBLPTR
	PAX		/USE X-REG AS BASE ADDRESS
	IAC		/SAVE A POINTER TO WD. 1 OF CTA
	DAC	TABTMP
	LAC*	UNIT	/GET UNIT NUMBER
	LRS!10000  3	/CLQ, THEN LEFT JUSTIFY UNIT NUMBER IN MQ
	LAC*	TABTMP	/GET PLATTER NO., 2ND WORD OF CTB
	AND	(77777)	/CLEAR UNIT NUMBER FIELD
	OMQ		/IMPOSE UNIT NUMBER
	DAC*	TABTMP	/RETURN TO 2ND WORD OF CPB
	CAL	DEALOC
	JMP*	DSKDAL	/RETURN
TABTMP	0		/POINTER TO WD. 1 OF CTA
/
DEALOC	11600		/MULTI-DISK DEALLOCATE
REQEV	0	/EVENT VARIABLE
	1	/LUN
TBLPTR	0	/CONTROL TABLE POINTER
DSKTYP	0	/DISK DEVICE CODE
	.END	DSKDAL