.TITLE DOUT-DIGITAL OUTPUT UDC.
/ 
/ 
/                   FIRST PRINTING, FEBRUARY 1974
/ 
/ THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO 
/ CHANGE WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED
/ AS A COMMITMENT BY DIGITAL EQUIPMENT CORPORATION.
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPON-
/ SIBILITY FOR ANY ERRORS THAT MAY APPEAR IN THIS
/ DOCUMENT.
/ 
/ THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FUR-
/ NISHED TO THE PURCHASER UNDER A LICENSE FOR USE ON
/ A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH
/ INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR 
/ USE IN SUCH SYSTEM, EXCEPT AS MAY OTHERWISE BE PRO-
/ VIDED IN WRITING BY DIGITAL.
/ 
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/ FOR THE USE OR RELIABILITY OF ITS SOFTWARE ON EQUIP-
/ MENT THAT IS NOT SUPPLIED BY DIGITAL.
/ 
/ COPYRIGHT (C) 1974, BY DIGITAL EQUIPMENT CORPORATION
/ 
/ 
        .EJECT
/EDIT 000 10-5-71
/COPYRIGHT 1971,DIGITAL EQUIPMENT CORP., MAYNARD,MASS.
/CALLING SEQUENCE:	CALL DOS(ILUN,ICHAN,IEV)
/	JMS* DOS
/	JMP .+4
/	ADDR. OF LUN
/	ADDR.OF CHANNEL NO.
/	ADDR. OF EV. (OPTIONAL)
/	NEXT INSTRUCTION.
/
/CALLING SEQUENCE:	CALL DOL(ILUN,ICHAN,LV,IEV)
/	JMS* DOL
/	JMP .+5
/	ADDR OF LUN
/	ADDR. OF CHANNEL NO.
/	ADDR. OF LV.
/	ADDR. OF EV.
/	NEXT INSTRUCTION.
/
/CALLING SEQUENCE:	CALL AO(ILUN,ICHAN,IVOLT,IEV)
/	JMS* AO
/	JMP .+5
/	ADDR. OF LUN
/	ADDR. OF CHANNEL NO.
/	ADDR. OF OUTPUT VOLTAGE.
/	ADDR. OF EV.
/	NEXT INSTRUCTION.
	.EJECT
/DOS(ILUN,ICHAN,IEV)- SINGLE SHSOT DIGITAL OUTPUT VIA LUN=ILUN.
/REQUEST A PULSE ON INDICATED DESCRETE CHANNEL NO. (ICHAN).  EV
/VARIABLE ARG. IS OPTIONAL.
/
/DOL(ILUN,ICHAN,LV,IEV)-LATCHING DIGITAL OUTPUT VIA LUN=ILUN.
/REQUEST TO SET INDICATED DESCRETE CHANNEL NO.(ICHAN) TO INDICATED
/POLARITY (LOGICAL VAR LV).  EV ARG. IS OPTIONAL.
/
/AO(ILUN,ICHAN,IVOLT,IEV)-ANALOG OUTPUT.  REQUEST TO SET
/INDICATED CHANNEL NO. (ICHAN) TO VOLTAGE PROPORTIONAL TO 
/INDICATED INTEGER (IVOLT) FOR 0-10 VOLTS.
/
	.EJECT
	.GLOBL DOL,DOS,AO,.DA
DOS	0		/SUBR. ENTRY.
	JMS*	.DA
	JMP	ARGE1
LUN1	0		/LOG. UNIT NO. ADDR.
CHAN1	0		/ADDR. OF CHANNEL NO.
EV1	0		/ADDR. OF EV.
ARGE1	LAC*	LUN1	/SET LUN.
	DAC	CPB2A
	LAC*	CHAN1	/MAKE LOW HANNEL =0.
	AAC	-1
	DAC	CPB3A
	LAC	EV1
	DAC	CPB1A
	DZM	EV1	/REINIT. EV ADDR.
	CAL	CALDOS
	JMP*	DOS
	.EJECT
DOL	0		/SUBR. ENTRY.
	JMS*	.DA
	JMP	ARGE2
LUN2	0	/ADDR. OF LUN.
CHAN2	0		/ADDR. OF CHANNEL NO.
L	0		/ADDR. OF LOGICAL VAR.
EV2	0		/ADDR. OF EV.
ARGE2	LAC*	LUN2
	DAC	CPB2B
	LAC*	CHAN2
	AAC	-1	/LOW CHAN. NO=0.
	DAC	CPB3B
	LAC*	L
	DAC	CPB4B
	LAC	EV2
	DAC	CPB1B
	DZM	EV2	/INIT EV.
	CAL	CALDOL
	JMP*	DOL
	.EJECT
AO	0		/SUBR. ENTRY.
	JMS*	.DA
	JMP	ARGE3
LUN3	0		/ADDR. OF LUN.
CHAN3	0		/ADDR. OF CHANNEL NO.
VOLT	0		/ADDR. OF VOLTAGE FACTOR.
EV3	0		/ADDR. OF EV.
ARGE3	LAC*	LUN3
	DAC	CPB2C
	LAC*	CHAN3
	AAC	-1	/LOW CHANNEL NO. =0
	DAC	CPB3C
	LAC*	VOLT
	DAC	CPB4C
	LAC	EV3
	DAC	CPB1C
	DZM	EV3
	CAL	CALAO
	JMP*	AO
	.EJECT
/
/CAL PARAM. BLOCKS.
/
/ANALOG OUTPUT.
CALAO	6700		/FUNCT. CODE.
CPB1C	0		/EV.
CPB2C	0		/LUN.
CPB3C	0		/CHAN. NO.
CPB4C	0		/OUTPUT VOLTAGE FACTOR.
/
/SINGLE SHOT DIGITAL OUTPUT.
/
CALDOS	6000		/FUNCT. CODE.
CPB1A	0		/EV
CPB2A	0		/LUN.
CPB3A	0		/CHAN. NO.
/
/DIGITAL OUTPUT LATCHING.
/
CALDOL	6100	/FUNCTION. CODE.
CPB1B	0		/EV.
CPB2B	0		/LUN.
CPB3B	0		/CHAN. NO.
CPB4B	0		/LOGICAL VALUE.
/
	.END