# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>

_mod=kipi-plugins
_cat=libraries/
_kdemod="${_mod/tde/kde}"

pkgname="tde-${_mod/tde-}"
pkgver=14.1.5
pkgrel=1
pkgdesc="The library for apps that want to use TDE kipi-plugins"
arch=('i686' 'x86_64' 'aarch64' 'armv7h' 'powerpc64le')
url="https://scm.trinitydesktop.org/scm/git/${_mod}"
license=('GPL')
provides=("${_mod}")
groups=('tde-complete')
depends=(
  'tde-tdelibs'
  'libgphoto2'
  'libgpod'
  'tde-libkdcraw'
  'tde-libkexiv2'
  'tde-libkipi'
  'tde-tdepim'
)
makedepends=(
  'autoconf'
  'pkgconfig'
)
optdepends=()
conflicts=("trinity-${_kdemod}" "kdemod3-${_kdemod}")
replaces=("trinity-${_mod}")
options=('staticlibs' 'libtool' '!strip')
install=

source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/${_cat}${_mod}-trinity-${pkgver}.tar.xz")
md5sums=('c02d09576af5d9538d8ab3efc5d1c8a6')

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity
[ -n "$TQTDIR" ] || TQTDIR=${TDEDIR}/tqt3

build() {
  ## Generate config files and update with autoreconf
  cd ${srcdir}/${pkgname#*-}-trinity-${pkgver}

  msg "Copying system libtool files...."
  cp -a /usr/share/libtool/build-aux/config.guess ./admin/
  cp -a /usr/share/libtool/build-aux/config.sub ./admin/
  cp /usr/share/aclocal/libtool.m4 ./admin/libtool.m4.in
  cp /usr/share/libtool/build-aux/ltmain.sh ./admin/ltmain.sh

  msg "Running make -f admin/Makefile.common ...."
  make -f admin/Makefile.common

  export PKG_CONFIG_PATH=${TDEDIR}/lib/pkgconfig:${TQTDIR}/lib/pkgconfig:${PKG_CONFIG_PATH}

  msg "Configuring - ${pkgname}..."
  ./configure \
    --prefix=${TDEDIR} \
    --with-tqt-dir=${TQTDIR} \
    --with-tqt-includes=${TQTDIR}/include \
    --with-tqt-libraries=${TQTDIR}/lib \
    --with-extra-includes="/usr/include/tqt" \
    --with-extra-libs="${TDEDIR}/lib:${TDEDIR}/lib/trinity" \
    --sysconfdir=${TDEDIR}/etc \
    --localstatedir=/var \
    --enable-closure

  msg "Building - ${pkgname}..."
  make $NUMJOBS
}

package() {
  msg "Packaging - $pkgname-$pkgver"
  cd ${srcdir}/${pkgname#*-}-trinity-${pkgver}
  make -j1 DESTDIR="${pkgdir}" install
}
