Another way is to
download files to a different networked computer, and then set up local
file transfer between the serial ports of the two machines. Again the
programme below could be used as the ARC end of that transfer. Serial data
transfer is full of problems till it starts to work. Check your connections
are correct, and the speed is the same at both ends!! (*CON.BAUD 1200 etc
for the ARC.) The final way is to use a DOS disk reader on the ARC, if
your networked machine is PC compatable. 

------------ArcTerm Mini Terminal with file save-----------------------
   10 REM >ArcTerm
   20 MODE0
   30 PRINT"ArcTerminal"
   40 PRINT"Now in terminal mode"
   50 PRINT"Use CTRL A to OPEN a file for output, CTRL B to CLOSE it"
   60 ONERROR OSCLI"FX2 0":OSCLI"CLOSE":REPORT:PRINT" at line ";ERL:END
   70 file%=FALSE
   80 REPEAT
   90 *FX2 2
  100 IF ADVAL(-1)>0 AND ADVAL(-3)>0 THEN
  110  char%=GET
  120  IF char%<3 THEN
  130   CASE char% OF
  140    WHEN 1:PROCopen :REM  ctrl'A'
  150    WHEN 2:PROCclose:REM  ctrl'B'
  160   ENDCASE
  170  ELSE
  180   SYS"OS_Byte",138,2,char%
  190  ENDIF
  200 ENDIF
  210 *FX2 1
  220 WHILE ADVAL(-2)>0
  230  char%=GET
  240  VDU char% AND &7F
  250  IF file% THEN BPUT#file%,char%
  260 ENDWHILE
  270 UNTIL0
  280 :
  290 DEFPROCopen
  300 INPUT'"Filename :"f$
  310 file%=OPENOUT f$
  320 PRINTf$" opened for output"
  330 ENDPROC
  340 :
  350 DEFPROCclose
  360 CLOSE#file%
  370 PRINT"File closed"
  380 file%=FALSE
  390 ENDPROC
--------------------End of ArcTerm----------------------------------